forked from hiveeyes/hanimandl
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathhanimandl.ino
2448 lines (2150 loc) · 86.7 KB
/
hanimandl.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
HaniMandl Version 0.2.13
------------------------
Copyright (C) 2018-2023 by Marc Vasterling, Marc Wetzel, Clemens Gruber, Marc Junker, Andreas Holzhammer, Johannes Kuder, Jeremias Bruker
2018-05 Marc Vasterling | initiale Version,
veröffentlicht in der Facebook-Gruppe "Imkerei und Technik. Eigenbau",
Marc Vasterling: "meinen Code kann jeder frei verwenden, ändern und hochladen wo er will, solange er nicht seinen eigenen Namen drüber setzt."
2018-06 Marc Vasterling | verbesserte Version,
ebenfalls veröffentlicht in der Facebook-Gruppe
2019-01 Marc Wetzel | Refakturierung und Dokumentation,
ebenfalls veröffentlicht in der Facebook-Gruppe
2019-02 Clemens Gruber | code beautifying mit kleineren Umbenennungen bei Funktionen und Variablen
Anpassung für Heltec WiFi Kit 32 (ESP32 onboard OLED)
- pins bei OLED-Initialisierung geändert
- pins geändert, um Konflikte mit hard wired pins des OLEDs zu vermeiden
2019-02 Clemens Gruber | Aktivierung der internen pull downs für alle digitalen Eingaenge
2019-02 Clemens Gruber | "normale" pins zu Vcc / GND geaendert um die Verkabelung etwas einfacher und angenehmer zu machen
2020-05 Andreas Holzhammer | Anpassungen an das veränderte ;-( pin-Layout der Version 2 des Heltec
wird verkauft als "New Wifi Kit 32" oder "Wifi Kit 32 V2"
2020-05 Marc Junker | - Erweiterung von Poti auf Rotary Encoder
- alle Serial.prints in #ifdef eingeschlossen
- "Glas" nun als Array mit individuellem Tara
- Korrekturwert und Auswahl der Füllmenge über Drücken & Drehen des Rotary einstellbar
2020-05 Andreas Holzhammer | - Tara pro abzufüllendem Glas automatisch anpassen (Variable tara_glas)
- Code läuft auch ohne Waage
2020-06 Andreas Holzhammer | - Code wahlweise mit Heltec V1 oder V2 nutzbar
- Code wahlweise mit Poti oder Rotary nutzbar
- Tara pro Glas einstellbar
- Öffnungswinkel für Maximale Öffnung und Feindosierung im Setup konfigurierbar
- Korrektur und Glasgröße im Automatikmodus per Rotary Encoder Button wählbar
- Preferences löschbar über Setup
- Gewicht blinkt bei Vollautomatik, wenn nicht vollständig gefüllt
- Nicht kalibrierte Waage anzeigen, fehlende Waage anzeigen
- Tara wird nur bei >20g gesetzt, verhindert den Autostart bei leerer Waage
- Tarieren der Waage bei jedem Start bis +-20g. Sonst Warnung
2020-07 Andreas Holzhammer | Version 0.2.4
- SCALE_READS auf 2 setzen? ca. 100ms schneller als 3, schwankt aber um +-1g
- Reihenfolge der Boot-Meldungen optimiert, damit nur relevante Warnungen ausgegeben werden
- Autokorrektur implementiert
- LOGO! und Umlaute (Anregung von Johannes Kuder)
- Stop-Taste verlässt Setup-Untermenüs (Anregung von Johannes Kuder)
- Preferences nur bei Änderung speichern
2020-07 Andreas Holzhammer | Version 0.2.5
- Anzeige der vorherigen Werte im Setup
- Kulanzwert für Autokorrektur einstellbar
- Setup aufgeräumt, minimaler Servowinkel einstellbar
2020-07 Andreas Holzhammer | Version 0.2.6
- Kalibrierung der Waage verbessert; Messewerte runden; Waage "aufheizen" vor Bootscreen
- Aktiver Piezo-Buzzer (Idee von Johannes Kuder)
2020-07 Johannes Kuder | Version 0.2.7
- Zählwerk für abgefüllte Gläser und Gewicht (nur im Automatikbetrieb)
2020-07 Jeremias Bruker | Version 0.2.8
- "GlasTyp" in allen Menüs und Automatikmodus integriert
- 5 Gläser können vom User im Menüpunkt "Fuellmenge" in Gewicht und GlasTyp konfiguriert werden
und werden nichtflüchtig gespeichert. So kann sich jeder User seine eigenen üblichen 5 Gläser anlegen
- Stabilisierung des Waagenwerts nach Wunsch (define FEHLERKORREKTUR_WAAGE)
- das Kalibriergewicht kann beim Kalibrierungsvorgang vom User verändert
werden (nicht jeder hat 500g als Eichgewicht) und wird nichtflüchtig gespeichert
- rotierendes Hauptmenü
- Umkehrbarer Servo für linksseitige Quetschhähne :-)
2020-10 Andreas Holzhammer | Version 0.2.8.1
- Bugfix: Servo konnte im Manuellen Modus unter Minimum bewegt werden
- Glastoleranz über Variable steuerbar auf +-20g angepasst
2020-12 Andreas Holzhammer | Version 0.2.9.1
- Fortschrittsanzeige eingebaut
- angepasst an ESP32Servo aus dem Bibliotheksverwalter
2021-01 Andreas Motl | Version 0.2.9.1
- PlatformIO-Support an neue Servo-Bibliothek angepasst
2021-02 Andreas Holzhammer | Version 0.2.10
- Korrektur zwischen -90 und +20 anpassbar
- Autokorrektur auch ohne Autostart
- Preferences Flash-schonender implementiert
2021-07 Andreas Holzhammer | Version 0.2.11
- Credits-Seite
- Fix für Rotary mit Schrittweite > 1
2021-11 Andreas Holzhammer | Version 0.2.12
- Glastoleranz einstellbar
- Komfortverstellung für Füllmengen (1g/5g/25g Schritte)
2023-01 Clemens Gruber | Version 0.2.13
- pin-Anpassungen für Hardware-Version V3 des Heltec "WiFi Kit 32 V3" mit wieder mal geändertem pin-Layout
- default HARDWARE_LEVEL ist nun 3 / Heltec V3
- Anpassungen für den ESP32 Arduino core Version ≥ 2.x
- Display, U8g2: HW statt SW im constructor (ggf. Probleme mit älteren Heltec-Versionen)
- Rotary: de-bouncing code im isr2 auskommentiert, da sie zu Abstürzen führte
2024-07 Michael Atzmüller | Version 0.2.13
- added Hardware Level for AZ-Delivery ESP32 Dev-Kit-C V2 and Fysetc Mini 12864 Display
This code is in the public domain.
Hinweise zur Hardware
---------------------
- bei allen digitalen Eingängen sind interne pull downs aktiviert, keine externen-Widerstände nötig!
*/
#include <Arduino.h>
#include <Wire.h>
#include <U8g2lib.h> /* aus dem Bibliotheksverwalter */
#include <HX711.h> /* aus dem Bibliotheksverwalter: "HX711 Arduino Library" by Bogdan Necula, Andreas Motl */
#include <ESP32Servo.h> /* aus dem Bibliotheksverwalter */
#include <Preferences.h> /* aus dem BSP von expressif, wird verfügbar wenn das richtige Board ausgewählt ist */
//
// Hier den Code auf die verwendete Hardware einstellen
//
#define HARDWARE_LEVEL 4 // 1 = originales Layout mit Schalter auf Pin 19/22/21
// 2 = Layout für Heltec V2 mit Schalter auf Pin 23/19/22
// 3 = Layout für Heltec V3 mit komplett anderer Pinbelegung
// 4 = Layout for AZ-Delivery ESP32 Dev-Kit-C V2 with Fysetc Mini 12864 (contains display and rotary encoder)
// #define SERVO_ERWEITERT // definieren, falls die Hardware mit dem alten Programmcode mit Poti aufgebaut wurde oder der Servo zu wenig fährt
// Sonst bleibt der Servo in Stop-Position einige Grad offen! Nach dem Update erst prüfen!
#define ROTARY_SCALE 2 // in welchen Schritten springt unser Rotary Encoder.
// Beispiele: KY-040 = 2, HW-040 = 1, für Poti-Betrieb auf 1 setzen
#define USE_ROTARY // Rotary benutzen
#define USE_ROTARY_SW // Taster des Rotary benutzen
//#define USE_POTI // Poti benutzen -> ACHTUNG, im Normalfall auch USE_ROTARY_SW deaktivieren!
//#define FEHLERKORREKTUR_WAAGE // falls Gewichtssprünge auftreten, können diese hier abgefangen werden
// Achtung, kann den Wägeprozess verlangsamen. Vorher Hardware prüfen.
#define QUETSCHHAHN_LINKS // Servo invertieren, falls der Quetschhahn von links geöffnet wird. Mindestens ein Exemplar bekannt
//
// Ende Benutzereinstellungen!
//
//
// Ab hier nur verstellen wenn Du genau weisst, was Du tust!
//
// #define isDebug 4 // serielle debug-Ausgabe aktivieren. Mit > 3 wird jeder Messdurchlauf ausgegeben
// mit 4 zusätzlich u.a. Durchlaufzeiten
// mit 5 zusätzlich rotary debug-Infos
// ACHTUNG: zu viel Serieller Output kann einen ISR-Watchdog Reset auslösen!
//#define POTISCALE // Poti simuliert eine Wägezelle, nur für Testbetrieb!
#define MAXIMALGEWICHT 5000 // Maximales Gewicht
// Ansteuerung der Waage
#define SCALE_READS 2 // Parameter für hx711 Library. Messwert wird aus der Anzahl gemittelt
#define SCALE_GETUNITS(n) (waage_vorhanden ? round(scale.get_units(n)) : simulate_scale(n) )
// Ansteuerung Servo
#ifdef QUETSCHHAHN_LINKS
#define SERVO_WRITE(n) servo.write(180-n)
#else
#define SERVO_WRITE(n) servo.write(n)
#endif
// Rotary Encoder Taster zieht Pegel auf Low, Start/Stop auf High!
#ifdef USE_ROTARY_SW
#define SELECT_SW outputSW
#define SELECT_PEGEL LOW
#else
#define SELECT_SW button_start_pin
#define SELECT_PEGEL HIGH
#endif
// Betriebsmodi
#define MODE_SETUP 0
#define MODE_AUTOMATIK 1
#define MODE_HANDBETRIEB 2
// Buzzer Sounds
#define BUZZER_SHORT 1
#define BUZZER_LONG 2
#define BUZZER_SUCCESS 3
#define BUZZER_ERROR 4
// ** Definition der pins
// ----------------------
#if HARDWARE_LEVEL == 4
// AZ-Delivery ESP32 Dev-Kit-C V2 with Fysetc Mini 12864
namespace Mini_12846_EXP1
{
// Pins Mini 12864 EXP1 Header
// 1. VCC
// 2. GND
// constexpr int LCD_Blue = ; // 3.
// constexpr int LCD_Green = ; // 4.
// constexpr int LCD_Red = ; // 5.
constexpr int LCD_Rst = 32; // 6.
constexpr int LCD_RS = 33; // 7.
constexpr int LCD_CS = 5; // 8.
constexpr int BTN_ENC = 15; // 9.
constexpr int BEEP = 25; // 10.
}
namespace Mini_12846_EXP2
{
// Pins Mini 12864 EXP2 Header
// 1. Kill
// 2. GND
// 3. RST
// 4. CD (only required for SD Card)
constexpr int MOSI = 23; // 5.
constexpr int BTN_EN1 = 0; // 6.
// 7. SS (for SD Card)
constexpr int BTN_EN2 = 26; // 8.
constexpr int SCK = 18; // 9.
// 10. MISO (only required for SD Card)
}
// Display
U8G2_UC1701_MINI12864_F_4W_HW_SPI u8g2(U8G2_R0, Mini_12846_EXP1::LCD_CS, Mini_12846_EXP1::LCD_RS, Mini_12846_EXP1::LCD_Rst);
// Buzzer
constexpr int buzzer_pin = Mini_12846_EXP1::BEEP;
// Rotary Encoder
constexpr int outputA = Mini_12846_EXP2::BTN_EN1;
constexpr int outputB = Mini_12846_EXP2::BTN_EN2;
constexpr int outputSW = Mini_12846_EXP1::BTN_ENC;
// Servo
constexpr int servo_pin = 2;
// 3x Schalter Ein 1 - Aus - Ein 2
constexpr int switch_betrieb_pin = 16;
constexpr int switch_vcc_pin = 39; // <- Vcc // Dummy value as it is connected to 3.3 Pin and 39 is input only
constexpr int switch_setup_pin = 4;
// Taster
constexpr int button_start_vcc_pin = 13; // <- Vcc
constexpr int button_start_pin = 12;
constexpr int button_stop_vcc_pin = 14; // <- Vcc
constexpr int button_stop_pin = 27;
// Wägezelle-IC
constexpr int hx711_dt_pin = 21;
constexpr int hx711_sck_pin = 22;
// Heltec Version 3
//
#elif HARDWARE_LEVEL == 3
// OLED fuer Heltec WiFi Kit 32 (ESP32 onboard OLED)
//U8G2_SSD1306_128X64_NONAME_F_SW_I2C u8g2(U8G2_R0, /* clock=*/ 15, /* data=*/ 4, /* reset=*/ 16);
// für den ESP32 Arduino core Version ≥ 2.x brauchen wir HW I2C, mit SW I2C läuft der code zu langsam
U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R0, /* reset=*/ 21, /* clock=*/ 18, /* data=*/ 17);
// Rotary Encoder
const int outputA = 47; // Clk
const int outputB = 48; // DT
const int outputSW = 26;
// Servo
const int servo_pin = 33;
// 3x Schalter Ein 1 - Aus - Ein 2
const int switch_betrieb_pin = 40;
const int switch_vcc_pin = 41; // <- Vcc
const int switch_setup_pin = 42;
const int vext_ctrl_pin = 36; // Vext control pin
// Taster
const int button_start_vcc_pin = 7; // <- Vcc
const int button_start_pin = 6;
const int button_stop_vcc_pin = 5; // <- Vcc
const int button_stop_pin = 4;
// Poti
//const int poti_pin = 39;
// Wägezelle-IC
const int hx711_sck_pin = 38;
const int hx711_dt_pin = 39;
// Buzzer - aktiver Piezo
static int buzzer_pin = 2;
#elif HARDWARE_LEVEL == 2
//
// Heltec Version 2
// OLED fuer Heltec WiFi Kit 32 (ESP32 onboard OLED)
//U8G2_SSD1306_128X64_NONAME_F_SW_I2C u8g2(U8G2_R0, /* clock=*/ 15, /* data=*/ 4, /* reset=*/ 16);
// für den ESP32 Arduino core Version ≥ 2.x brauchen wir HW I2C, mit SW I2C läuft der code zu langsam
U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R0, /* reset=*/ 16, /* clock=*/ 15, /* data=*/ 4);
// Rotary Encoder
const int outputA = 33;
const int outputB = 26;
const int outputSW = 32;
// Servo
const int servo_pin = 2;
// 3x Schalter Ein 1 - Aus - Ein 2
const int switch_betrieb_pin = 23;
const int switch_vcc_pin = 19; // <- Vcc
const int switch_setup_pin = 22;
const int vext_ctrl_pin = 21; // Vext control pin
// Taster
const int button_start_vcc_pin = 13; // <- Vcc
const int button_start_pin = 12;
const int button_stop_vcc_pin = 14; // <- Vcc
const int button_stop_pin = 27;
// Poti
const int poti_pin = 39;
// Wägezelle-IC
const int hx711_sck_pin = 17;
const int hx711_dt_pin = 5;
// Buzzer - aktiver Piezo
static int buzzer_pin = 25;
#elif HARDWARE_LEVEL == 1
//
// Heltec Version 1
// OLED fuer Heltec WiFi Kit 32 (ESP32 onboard OLED)
U8G2_SSD1306_128X64_NONAME_F_SW_I2C u8g2(U8G2_R0, /* clock=*/ 15, /* data=*/ 4, /* reset=*/ 16);
//U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R0, /* reset=*/ 16, /* clock=*/ 15, /* data=*/ 4); // HW I2C crashed den Code
// Rotary Encoder
const int outputA = 33;
const int outputB = 26;
const int outputSW = 32;
// Servo
const int servo_pin = 2;
// 3x Schalter Ein 1 - Aus - Ein 2
const int switch_betrieb_pin = 19;
const int switch_vcc_pin = 22; // <- Vcc
const int switch_setup_pin = 21;
// Taster
const int button_start_vcc_pin = 13; // <- Vcc
const int button_start_pin = 12;
const int button_stop_vcc_pin = 14; // <- Vcc
const int button_stop_pin = 27;
// Poti
const int poti_pin = 39;
// Wägezelle-IC
const int hx711_sck_pin = 17;
const int hx711_dt_pin = 5;
// Buzzer - aktiver Piezo
static int buzzer_pin = 25;
#else
#error Hardware Level nicht definiert! Korrektes #define setzen!
#endif
Servo servo;
HX711 scale;
Preferences preferences;
// Datenstrukturen für Rotary Encoder
struct rotary {
int Value;
int Minimum;
int Maximum;
int Step;
};
#define SW_WINKEL 0
#define SW_KORREKTUR 1
#define SW_MENU 2
struct rotary rotaries[3]; // Werden in setup() initialisiert
int rotary_select = SW_WINKEL;
static boolean rotating = false; // debounce management für Rotary Encoder
// Füllmengen für 5 verschiedene Gläser
struct glas {
int Gewicht;
int GlasTyp; //JB
int Tara;
int TripCount; //Kud
int Count; //Kud
};
const char *GlasTypArray[3] = { "DIB", "TOF", "DEE"};//DIB = DeutscherImkerBund-Glas DEE= DeepTwist-Glas TOF= TwistOff-Glas //JB
struct glas glaeser[5] = {
{ 125, 0, -9999, 0, 0 },
{ 250, 1, -9999, 0, 0 },
{ 250, 2, -9999, 0, 0 },
{ 500, 1, -9999, 0, 0 },
{ 500, 0, -9999, 0, 0 }
};
// Allgemeine Variablen
int i; // allgemeine Zählvariable
int pos; // aktuelle Position des Poti bzw. Rotary
int gewicht; // aktuelles Gewicht
int tara; // Tara für das ausgewählte Glas, für Automatikmodus
int tara_glas; // Tara für das aktuelle Glas, falls Glasgewicht abweicht
long gewicht_leer; // Gewicht der leeren Waage
float faktor; // Skalierungsfaktor für Werte der Waage
int fmenge; // ausgewählte Füllmenge
int fmenge_index; // Index in gläser[]
int korrektur; // Korrekturwert für Abfüllmenge
int autostart; // Vollautomatik ein/aus
int autokorrektur; // Autokorrektur ein/aus
int kulanz_gr; // gewollte Überfüllung im Autokorrekturmodus in Gramm
int winkel; // aktueller Servo-Winkel
int winkel_hard_min = 0; // Hard-Limit für Servo
int winkel_hard_max = 180; // Hard-Limit für Servo
int winkel_min = 0; // konfigurierbar im Setup
int winkel_max = 85; // konfigurierbar im Setup
int winkel_fein = 35; // konfigurierbar im Setup
float fein_dosier_gewicht = 60; // float wegen Berechnung des Schliesswinkels
int servo_aktiv = 0; // Servo aktivieren ja/nein
int kali_gewicht = 500; // frei wählbares Gewicht zum kalibrieren
char ausgabe[30]; // Fontsize 12 = 13 Zeichen maximal in einer Zeile
int modus = -1; // Bei Modus-Wechsel den Servo auf Minimum fahren
int auto_aktiv = 0; // Für Automatikmodus - System ein/aus?
int waage_vorhanden = 0; // HX711 nicht ansprechen, wenn keine Waage angeschlossen ist, sonst Crash
long preferences_chksum; // Checksumme, damit wir nicht sinnlos Prefs schreiben
int buzzermode = 0; // 0 = aus, 1 = ein. TODO: Tastentöne als buzzermode 2?
bool gezaehlt = true; // Kud Zähl-Flag
bool setup_modern = 1; // Setup als rotierendes Menu
int glastoleranz = 20; // Gewicht für autostart darf um +-20g schwanken, insgesamt also 40g!
// Simuliert die Dauer des Wägeprozess, wenn keine Waage angeschlossen ist. Wirkt sich auf die Blinkfrequenz im Automatikmodus aus.
long simulate_scale(int n) {
long sim_gewicht = 9500;
while (n-- >= 1) {
delay(10); // empirisch ermittelt. n=2: 10, n=3: 40, n=4: 50
}
#ifdef POTISCALE
sim_gewicht = (map(analogRead(poti_pin), 0, 4095, 0, 700));
#endif
return sim_gewicht;
}
#ifdef USE_ROTARY_SW
// Rotary Taster. Der Interrupt kommt nur im Automatikmodus zum Tragen und nur wenn der Servo inaktiv ist.
// Der Taster schaltet in einen von drei Modi, in denen unterschiedliche Werte gezählt werden.
void IRAM_ATTR isr1() {
static unsigned long last_interrupt_time = 0;
unsigned long interrupt_time = millis();
if (interrupt_time - last_interrupt_time > 300) { // If interrupts come faster than 300ms, assume it's a bounce and ignore
if ( modus == MODE_AUTOMATIK && servo_aktiv == 0 ) { // nur im Automatik-Modus interessiert uns der Click
rotary_select = (rotary_select + 1) % 3;
#ifdef isDebug
Serial.print("Rotary Button changed to ");
Serial.println(rotary_select);
#endif
}
last_interrupt_time = interrupt_time;
}
}
#endif
#ifdef USE_ROTARY
// Rotary Encoder. Zählt in eine von drei Datenstrukturen:
// SW_WINKEL = Einstellung des Servo-Winkels
// SW_KORREKTUR = Korrekturfaktor für Füllgewicht
// SW_MENU = Zähler für Menuauswahlen
void IRAM_ATTR isr2() {
static int aState;
static int aLastState = 2; // reale Werte sind 0 und 1
// auskommentiert, da vermutlich das delay in der isr-Funktion ein reset ab ESP32 Arduino core Version ≥ 2.x auslöst
// beobachten, ob damit das bouncing ein Problem wird, in rudimentären Tests konnte ich (cg) nichts negatives beobachten
// if ( rotating ) delay (1); // wait a little until the bouncing is done
aState = digitalRead(outputA); // Reads the "current" state of the outputA
if (aState != aLastState) {
// If the outputB state is different to the outputA state, that means the encoder is rotating clockwise
if (digitalRead(outputB) != aState) {
rotaries[rotary_select].Value -= rotaries[rotary_select].Step;
} else { // counter-clockwise
rotaries[rotary_select].Value += rotaries[rotary_select].Step;
}
rotaries[rotary_select].Value = constrain( rotaries[rotary_select].Value, rotaries[rotary_select].Minimum, rotaries[rotary_select].Maximum );
rotating = false;
#ifdef isDebug
#if isDebug >= 5
Serial.print(" Rotary Value changed to ");
Serial.println(getRotariesValue(rotary_select));
#endif
#endif
}
aLastState = aState; // Updates the previous state of the outputA with the current state
}
#endif
//
// Skalierung des Rotaries für verschiedene Rotary Encoder oder Simulation über Poti
int getRotariesValue( int rotary_mode ) {
#ifdef USE_ROTARY
return ( (rotaries[rotary_mode].Value - (rotaries[rotary_mode].Value % (rotaries[rotary_mode].Step*ROTARY_SCALE) )) / ROTARY_SCALE );
#elif defined USE_POTI
int poti_min = (rotaries[rotary_mode].Minimum / ROTARY_SCALE);
int poti_max = (rotaries[rotary_mode].Maximum / ROTARY_SCALE);
if( rotaries[rotary_mode].Step > 0 ) {
return (map(analogRead(poti_pin), 0, 4095, poti_min, poti_max));
} else {
return (map(analogRead(poti_pin), 0, 4095, poti_max, poti_min));
}
#else
#error Weder Rotary noch Poti aktiviert!
#endif
}
void setRotariesValue( int rotary_mode, int rotary_value ) {
rotaries[rotary_mode].Value = rotary_value * ROTARY_SCALE;
}
void initRotaries( int rotary_mode, int rotary_value, int rotary_min, int rotary_max, int rotary_step ) {
rotaries[rotary_mode].Value = rotary_value * ROTARY_SCALE;
rotaries[rotary_mode].Minimum = rotary_min * ROTARY_SCALE;
rotaries[rotary_mode].Maximum = rotary_max * ROTARY_SCALE;
rotaries[rotary_mode].Step = rotary_step;
#ifdef isDebug
Serial.print("initRotaries...");
Serial.print(" Rotary Mode: "); Serial.print(rotary_mode);
Serial.print(" rotary_value: "); Serial.print(rotary_value);
Serial.print(" Value: "); Serial.print(rotaries[rotary_mode].Value);
Serial.print(" Min: "); Serial.print(rotaries[rotary_mode].Minimum);
Serial.print(" Max: "); Serial.print(rotaries[rotary_mode].Maximum);
Serial.print(" Step: "); Serial.print(rotaries[rotary_mode].Step);
Serial.print(" Scale: "); Serial.println(ROTARY_SCALE);
#endif
}
// Ende Funktionen für den Rotary Encoder
//
void getPreferences(void) {
preferences.begin("EEPROM", false); // Parameter aus dem EEPROM lesen
faktor = preferences.getFloat("faktor", 0.0); // falls das nicht gesetzt ist -> Waage ist nicht kalibriert
pos = preferences.getUInt("pos", 0);
gewicht_leer = preferences.getUInt("gewicht_leer", 0);
korrektur = preferences.getUInt("korrektur", 0);
autostart = preferences.getUInt("autostart", 0);
autokorrektur = preferences.getUInt("autokorrektur", 0);
kulanz_gr = preferences.getUInt("kulanz_gr", 5);
fmenge_index = preferences.getUInt("fmenge_index", 3);
winkel_min = preferences.getUInt("winkel_min", winkel_min);
winkel_max = preferences.getUInt("winkel_max", winkel_max);
winkel_fein = preferences.getUInt("winkel_fein", winkel_fein);
buzzermode = preferences.getUInt("buzzermode", buzzermode);
kali_gewicht = preferences.getUInt("kali_gewicht", kali_gewicht); //JB
setup_modern = preferences.getUInt("setup_modern", setup_modern);
glastoleranz = preferences.getUInt("glastoleranz", glastoleranz);
preferences_chksum = faktor + pos + gewicht_leer + korrektur + autostart + autokorrektur + fmenge_index + winkel_min + winkel_max + winkel_fein + kulanz_gr + buzzermode + kali_gewicht + setup_modern + glastoleranz;
i = 0;
int ResetGewichte[] = {125,250,250,500,500,};
int ResetGlasTyp[] = {0,1,2,1,0,};
while( i < 5) {
sprintf(ausgabe, "Gewicht%d", i); //JB
glaeser[i].Gewicht = preferences.getInt(ausgabe, ResetGewichte[i]); //JB
preferences_chksum += glaeser[i].Gewicht; //JB
sprintf(ausgabe, "GlasTyp%d", i); //JB
glaeser[i].GlasTyp = preferences.getInt(ausgabe, ResetGlasTyp[i]); //JB
preferences_chksum += glaeser[i].GlasTyp; //JB
sprintf(ausgabe, "Tara%d", i);
glaeser[i].Tara= preferences.getInt(ausgabe, -9999);
preferences_chksum += glaeser[i].Tara;
sprintf(ausgabe, "TripCount%d", i); //Kud
glaeser[i].TripCount = preferences.getInt(ausgabe, 0);//Kud
preferences_chksum += glaeser[i].TripCount;
sprintf(ausgabe, "Count%d", i); //Kud
glaeser[i].Count = preferences.getInt(ausgabe, 0);//Kud
preferences_chksum += glaeser[i].Count;
i++;
}
preferences.end();
#ifdef isDebug
Serial.println("get Preferences:");
Serial.print("pos = "); Serial.println(pos);
Serial.print("faktor = "); Serial.println(faktor);
Serial.print("gewicht_leer = "); Serial.println(gewicht_leer);
Serial.print("korrektur = "); Serial.println(korrektur);
Serial.print("autostart = "); Serial.println(autostart);
Serial.print("autokorrektur = ");Serial.println(autokorrektur);
Serial.print("kulanz_gr = "); Serial.println(kulanz_gr);
Serial.print("fmenge_index = "); Serial.println(fmenge_index);
Serial.print("winkel_min = "); Serial.println(winkel_min);
Serial.print("winkel_max = "); Serial.println(winkel_max);
Serial.print("winkel_fein = "); Serial.println(winkel_fein);
Serial.print("buzzermode = "); Serial.println(buzzermode);
Serial.print("kali_gewicht = "); Serial.println(kali_gewicht);//JB
Serial.print("setup_modern = "); Serial.println(setup_modern);
Serial.print("glastoleranz = "); Serial.println(glastoleranz);
i = 0;
while( i < 5 ) {
sprintf(ausgabe, "Gewicht%d = ", i);
Serial.print(ausgabe);
Serial.println(glaeser[i].Gewicht);
sprintf(ausgabe, "GlasTyp%d = ", i);
Serial.print(ausgabe);
Serial.println(GlasTypArray[glaeser[i].GlasTyp]);
sprintf(ausgabe, "Tara%d = ", i);
Serial.print(ausgabe);
Serial.println(glaeser[i].Tara);
i++;
}
Serial.print("Checksumme:");
Serial.println(preferences_chksum);
#endif
}
void setPreferences(void) {
long preferences_newchksum;
int winkel = getRotariesValue(SW_WINKEL);
int i;
preferences.begin("EEPROM", false);
// Winkel-Einstellung separat behandeln, ändert sich häufig
if ( winkel != preferences.getUInt("pos", 0) ) {
preferences.putUInt("pos", winkel);
#ifdef isDebug
Serial.print("winkel gespeichert: ");
Serial.println(winkel);
#endif
}
// Counter separat behandeln, ändert sich häufig
for ( i=0 ; i < 5; i++ ) {
sprintf(ausgabe, "TripCount%d", i);
if ( glaeser[i].TripCount != preferences.getInt(ausgabe, 0) )
preferences.putInt(ausgabe, glaeser[i].TripCount);
sprintf(ausgabe, "Count%d", i);
if ( glaeser[i].Count != preferences.getInt(ausgabe, 0) )
preferences.putInt(ausgabe, glaeser[i].Count);
#ifdef isDebug
Serial.print("Counter gespeichert: Index ");
Serial.print(i);
Serial.print(" Trip ");
Serial.print(glaeser[fmenge_index].TripCount);
Serial.print(" Gesamt ");
Serial.println(glaeser[fmenge_index].Count);
#endif
}
// Den Rest machen wir gesammelt, das ist eher statisch
preferences_newchksum = faktor + gewicht_leer + korrektur + autostart + autokorrektur +
fmenge_index + winkel_min + winkel_max + winkel_fein + kulanz_gr +
buzzermode + kali_gewicht + setup_modern + glastoleranz;
i = 0;
while( i < 5 ) {
preferences_newchksum += glaeser[i].Gewicht;//JB
preferences_newchksum += glaeser[i].GlasTyp;//JB
preferences_newchksum += glaeser[i].Tara;
// preferences_newchksum += glaeser[i].TripCount;//Kud
// preferences_newchksum += glaeser[i].Count;//Kud
i++;
}
if( preferences_newchksum == preferences_chksum ) {
#ifdef isDebug
// Serial.println("Preferences unverändert");
#endif
return;
}
preferences_chksum = preferences_newchksum;
// preferences.begin("EEPROM", false);
preferences.putFloat("faktor", faktor);
preferences.putUInt("gewicht_leer", gewicht_leer);
// preferences.putUInt("pos", winkel);
preferences.putUInt("korrektur", korrektur);
preferences.putUInt("autostart", autostart);
preferences.putUInt("autokorrektur", autokorrektur);
preferences.putUInt("kulanz_gr", kulanz_gr);
preferences.putUInt("winkel_min", winkel_min);
preferences.putUInt("winkel_max", winkel_max);
preferences.putUInt("winkel_fein", winkel_fein);
preferences.putUInt("fmenge_index", fmenge_index);
preferences.putUInt("buzzermode", buzzermode);
preferences.putUInt("kali_gewicht", kali_gewicht);//JB
preferences.putUInt("setup_modern", setup_modern);
preferences.putUInt("glastoleranz", glastoleranz);
i = 0;
while( i < 5 ) {
sprintf(ausgabe, "Gewicht%d", i);
preferences.putInt(ausgabe, glaeser[i].Gewicht);
sprintf(ausgabe, "GlasTyp%d", i);
preferences.putInt(ausgabe, glaeser[i].GlasTyp);
sprintf(ausgabe, "Tara%d", i);
preferences.putInt(ausgabe, glaeser[i].Tara);
// sprintf(ausgabe, "TripCount%d", i);
// preferences.putInt(ausgabe, glaeser[i].TripCount);//Kud
// sprintf(ausgabe, "Count%d", i);
// preferences.putInt(ausgabe, glaeser[i].Count);//Kud
i++;
}
preferences.end();
#ifdef isDebug
Serial.println("Set Preferences:");
Serial.print("pos = "); Serial.println(winkel);
Serial.print("faktor = "); Serial.println(faktor);
Serial.print("gewicht_leer = "); Serial.println(gewicht_leer);
Serial.print("korrektur = "); Serial.println(korrektur);
Serial.print("autostart = "); Serial.println(autostart);
Serial.print("autokorrektur = ");Serial.println(autokorrektur);
Serial.print("kulanz_gr = "); Serial.println(kulanz_gr);
Serial.print("fmenge_index = "); Serial.println(fmenge_index);
Serial.print("winkel_min = "); Serial.println(winkel_min);
Serial.print("winkel_max = "); Serial.println(winkel_max);
Serial.print("winkel_fein = "); Serial.println(winkel_fein);
Serial.print("buzzermode = "); Serial.println(buzzermode);
Serial.print("kali_gewicht = "); Serial.println(kali_gewicht); //JB
Serial.print("setup_modern = "); Serial.println(setup_modern);
Serial.print("glastoleranz = "); Serial.println(glastoleranz);
i = 0;
while( i < 5 ) {
sprintf(ausgabe, "Gewicht%d = ", i);
Serial.print(ausgabe); Serial.println(glaeser[i].Gewicht);
sprintf(ausgabe, "GlasTyp%d = ", i);
Serial.print(ausgabe); Serial.println(GlasTypArray[glaeser[i].GlasTyp]);
sprintf(ausgabe, "Tara%d = ", i);
Serial.print(ausgabe); Serial.println(glaeser[i].Tara);
i++;
}
#endif
}
void setupTripCounter(void) { //Kud
int j;
i = 1;
float TripAbfuellgewicht = 0;
while (i > 0) { //Erster Screen: Anzahl pro Glasgröße
j = 0;
if ((digitalRead(button_stop_pin)) == HIGH)
return;
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
//verlasse Screen
i = 0;
delay(250);
}
u8g2.setFont(u8g2_font_courB10_tf);
u8g2.clearBuffer();
while ( j < 5 ) {
u8g2.setCursor(1, 10 + (j * 13));
sprintf(ausgabe, "%4dg%3s", glaeser[j].Gewicht, GlasTypArray[glaeser[j].GlasTyp]);
u8g2.print(ausgabe);
u8g2.setCursor(50, 10 + (j * 13));
sprintf(ausgabe, "%5d St.", glaeser[j].TripCount);
u8g2.print(ausgabe);
j++;
}
u8g2.sendBuffer();
delay(100);
}
i = 1;
while (i > 0) { //Zweiter Screen: Gewicht pro Glasgröße
j = 0;
if ((digitalRead(button_stop_pin)) == HIGH)
return;
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
//verlasse Screen
i = 0;
delay(250);
}
u8g2.setFont(u8g2_font_courB10_tf);
u8g2.clearBuffer();
while ( j < 5 ) {
u8g2.setCursor(1, 10 + (j * 13));
sprintf(ausgabe, "%4dg%3s", glaeser[j].Gewicht,GlasTypArray[glaeser[j].GlasTyp]);
u8g2.print(ausgabe);
u8g2.setCursor(65, 10 + (j * 13));
// Serial.println(glaeser[j].Gewicht);
// Serial.print("\t");
// Serial.print(glaeser[j].TripCount);
// Serial.print("\t");
// Serial.print(glaeser[j].Gewicht * glaeser[j].TripCount / 1000.0);
// Serial.println();
sprintf(ausgabe, "%5.1fkg", glaeser[j].Gewicht * glaeser[j].TripCount / 1000.0);
u8g2.print(ausgabe);
j++;
}
u8g2.sendBuffer();
delay(100);
}
i = 1;
while (i > 0) { //Dritter Screen: Gesamtgewicht
TripAbfuellgewicht = 0;
j = 0;
if ((digitalRead(button_stop_pin)) == HIGH)
return;
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
//verlasse Screen
i = 0;
delay(250);
}
while ( j < 5) {
TripAbfuellgewicht += glaeser[j].Gewicht * glaeser[j].TripCount / 1000.0;
j++;
}
u8g2.clearBuffer();
u8g2.setFont(u8g2_font_courB14_tf);
u8g2.setCursor(5, 15);
u8g2.print("Summe Trip:");
u8g2.setFont(u8g2_font_courB18_tf);
u8g2.setCursor(10, 50);
sprintf(ausgabe, "%5.1fkg", TripAbfuellgewicht);
u8g2.print(ausgabe);
u8g2.sendBuffer();
delay(100);
}
i = 1;
while (i > 0) { //Vierter Screen: Zurücksetzen
initRotaries(SW_MENU, 1, 0, 1, -1);
i = 1;
while (i > 0) {
if ((digitalRead(button_stop_pin)) == HIGH)
return;
pos = getRotariesValue(SW_MENU);
u8g2.setFont(u8g2_font_courB10_tf);
u8g2.clearBuffer();
u8g2.setCursor(10, 12); u8g2.print("Reset");
u8g2.setCursor(10, 28); u8g2.print("Abbrechen");
u8g2.setCursor(0, 12 + ((pos) * 16));
u8g2.print("*");
u8g2.sendBuffer();
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
u8g2.setCursor(105, 12 + ((pos) * 16));
u8g2.print("OK");
u8g2.sendBuffer();
if ( pos == 0) {
j = 0;
while ( j < 5 ) {
glaeser[j].TripCount = 0;
j++;
}
setPreferences();
}
delay(1000);
i = 0;
}
}
}
}
void setupCounter(void) { //Kud
int j;
i = 1;
float Abfuellgewicht = 0;
while (i > 0) { //Erster Screen: Anzahl pro Glasgröße
j = 0;
if ((digitalRead(button_stop_pin)) == HIGH)
return;
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
//verlasse Screen
i = 0;
delay(250);
}
u8g2.setFont(u8g2_font_courB10_tf);
u8g2.clearBuffer();
while ( j < 5 ) {
u8g2.setCursor(1, 10 + (j * 13));
sprintf(ausgabe, "%4dg%3s", glaeser[j].Gewicht,GlasTypArray[glaeser[j].GlasTyp]);
u8g2.print(ausgabe);
u8g2.setCursor(50, 10 + (j * 13));
sprintf(ausgabe, "%5d St.", glaeser[j].Count);
u8g2.print(ausgabe);
j++;
}
u8g2.sendBuffer();
delay(100);
}
i = 1;
while (i > 0) { //Zweiter Screen: Gewicht pro Glasgröße
j = 0;
if ((digitalRead(button_stop_pin)) == HIGH)
return;
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
//verlasse Screen
i = 0;
delay(250);
}
u8g2.setFont(u8g2_font_courB10_tf);
u8g2.clearBuffer();
while ( j < 5) {
u8g2.setCursor(1, 10 + (j * 13));
sprintf(ausgabe, "%4dg%3s", glaeser[j].Gewicht,GlasTypArray[glaeser[j].GlasTyp]);
u8g2.print(ausgabe);
u8g2.setCursor(65, 10 + (j * 13));
// Serial.println(glaeser[j].Gewicht);
// Serial.print("\t");
// Serial.print(glaeser[j].Count);
// Serial.print("\t");
// Serial.print(glaeser[j].Gewicht * glaeser[j].Count / 1000.0);
// Serial.println();
sprintf(ausgabe, "%5.1fkg", glaeser[j].Gewicht * glaeser[j].Count / 1000.0);
u8g2.print(ausgabe);
j++;
}
u8g2.sendBuffer();
delay(100);
}
i = 1;
while (i > 0) { //Dritter Screen: Gesamtgewicht
Abfuellgewicht = 0;
j = 0;
if ((digitalRead(button_stop_pin)) == HIGH)
return;
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
//verlasse Screen
i = 0;
delay(250);
}
while ( j < 5 ) {
Abfuellgewicht += glaeser[j].Gewicht * glaeser[j].Count / 1000.0;
j++;
}
u8g2.clearBuffer();
u8g2.setFont(u8g2_font_courB14_tf);
u8g2.setCursor(1, 15);
u8g2.print("Summe:");
u8g2.setFont(u8g2_font_courB18_tf);
u8g2.setCursor(10, 50);
sprintf(ausgabe, "%5.1fkg", Abfuellgewicht);
u8g2.print(ausgabe);
u8g2.sendBuffer();
delay(100);
}
i = 1;
while (i > 0) { //Vierter Screen: Zurücksetzen
initRotaries(SW_MENU, 1, 0, 1, -1);
i = 1;
while (i > 0) {
if ((digitalRead(button_stop_pin)) == HIGH)
return;
pos = getRotariesValue(SW_MENU);
u8g2.setFont(u8g2_font_courB10_tf);
u8g2.clearBuffer();
u8g2.setCursor(10, 12); u8g2.print("Reset");
u8g2.setCursor(10, 28); u8g2.print("Abbrechen");
u8g2.setCursor(0, 12 + ((pos) * 16));
u8g2.print("*");
u8g2.sendBuffer();
if ((digitalRead(SELECT_SW)) == SELECT_PEGEL) {
u8g2.setCursor(105, 12 + ((pos) * 16));
u8g2.print("OK");
u8g2.sendBuffer();
if ( pos == 0) {
j = 0;
while ( j < 5 ) {
glaeser[j].Count = 0;
glaeser[j].TripCount = 0;
j++;
}
setPreferences();
}
delay(1000);
i = 0;
}
}
}
}