build.gradle

plugins {
    id("maven-publish")
    id("fabric-loom").version("0.12-SNAPSHOT").apply(false)
    // https://github.com/Juuxel/LoomQuiltflower
    id("io.github.juuxel.loom-quiltflower").version("1.7.0").apply(false)
    // https://github.com/ReplayMod/preprocessor
    // https://github.com/Fallen-Breath/preprocessor
    id("com.replaymod.preprocess").version("b7207cffa9")
}

preprocess {
    def mc114 = createNode("1.14.4", 1_14_04, "mojang")
    def mc115 = createNode("1.15.2", 1_15_02, "mojang")
    def mc116 = createNode("1.16.5", 1_16_05, "mojang")
    def mc117 = createNode("1.17.1", 1_17_01, "mojang")
    def mc118 = createNode("1.18.2", 1_18_02, "mojang")
    def mc119 = createNode("1.19.2", 1_19_02, "mojang") // root

    mc114.link(mc115, null)
    mc115.link(mc116, null)
    mc116.link(mc117, null)
    mc117.link(mc118, null)
    mc118.link(mc119, null)
}

def ENV = System.getenv()
String realVersion = "${project.mod_version}"

if (ENV.BUILD_NUMBER) {
    realVersion += ".${ENV.BUILD_NUMBER}"
} else {
    realVersion += ".0"
}

if (ENV.COMMIT_SHA) {
    realVersion += "+${ENV.COMMIT_SHA}"
}

if (ENV.BUILD_TYPE) {
    if (ENV.BUILD_TYPE == "RELEASE") {
        realVersion += "-stable"
    } else if (ENV.BUILD_TYPE == "BETA") {
        realVersion += "-beta"
    }
} else {
    realVersion += "-dev"
}

version = realVersion