build.gradle

/*
 * Copyright 2020 Mohist-Community
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id 'com.github.johnrengelman.shadow' version '5.2.0'
    id 'war'
    id 'maven-publish'
}

allprojects {
    group = 'red.mohist.sodionauth'
    version = '2.0-SNAPSHOT'
    // Notice another version
    // red.mohist.sodionauth.sponge.SpongeLoader
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'maven-publish'

    repositories {
        mavenLocal()
        maven {
            url = 'https://repo.maven.apache.org/maven2'
        }

        maven {
            url = 'https://papermc.io/repo/repository/maven-public/'
        }

        maven {
            url = 'https://oss.sonatype.org/content/groups/public/'
        }

        maven {
            url = 'https://repo.dmulloy2.net/nexus/repository/public/'
        }

        maven {
            url = 'https://www.jitpack.io'
        }
    }

    sourceCompatibility = '1.8'

    tasks.withType(JavaCompile) {
        options.encoding = 'UTF-8'
    }

    afterEvaluate {
        publishing {
            publications {
                Library(MavenPublication) {
                    if (!project.name.equals("SodionAuth-Fabric")) {
                        from components.java
                        if (project.tasks.findByName("shadowJar") != null) {
                            artifact shadowJar
                        }
                    }
                }
            }
        }
    }
}

// configure the maven publication
publishing {
    publications {
        //noinspection GroovyAssignabilityCheck
        shadow(MavenPublication) {
            from components.java
            artifact shadowJar
        }
    }

    // select the repositories you want to publish to
    repositories {
        // uncomment to publish to the local maven
        // mavenLocal()
    }
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    // compile(project(path: ":SodionAuth-Core", configuration: "shadow"))
    implementation(project(path: ":SodionAuth-Bukkit", configuration: "shadow"))
    implementation(project(path: ":SodionAuth-Fabric", configuration: "remapShadow"))
    implementation(project(path: ":SodionAuth-Sponge", configuration: "shadow"))
}

assemble.dependsOn(shadowJar)