build.gradle

plugins {
    id 'fabric-loom' version '1.8-SNAPSHOT'
    id 'maven-publish'
}

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    mavenLocal()
    maven { url = "https://maven.shedaniel.me/" }
    maven { url = "https://maven.terraformersmc.com/" }
    maven { url = "https://maven.ladysnake.org/releases" }
    maven { url = "https://maven.wispforest.io/" }
    maven { url = "https://api.modrinth.com/maven/" }
    maven { url = "https://jitpack.io" }
    maven { url = "https://maven.jamieswhiteshirt.com/libs-release" }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"

    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // OwO
    annotationProcessor modImplementation("io.wispforest:owo-lib:${project.owo_version}")

    // REI
    modLocalRuntime "me.shedaniel:RoughlyEnoughItems-fabric:${project.rei_version}"
    modCompileOnly("me.shedaniel:RoughlyEnoughItems-default-plugin:${project.rei_version}")
    modCompileOnly "me.shedaniel:RoughlyEnoughItems-api-fabric:${project.rei_version}"
    //modRuntimeOnly "dev.architectury:architectury-fabric:${project.architectury_version}"

    // emi
    modCompileOnly "dev.emi:emi-fabric:${emi_version}"

    // MM + AF + Magna + CCA
    modImplementation "maven.modrinth:mythicmetals:${project.mm_version}"
    modRuntimeOnly "maven.modrinth:alloy-forgery:${project.af_version}"
    modRuntimeOnly "dev.onyxstudios.cardinal-components-api:cardinal-components-base:${project.cca_version}"
    modRuntimeOnly "dev.onyxstudios.cardinal-components-api:cardinal-components-entity:${project.cca_version}"

    // Lithium
    modCompileOnly("maven.modrinth:lithium:${project.leetheum_version}")
    modRuntimeOnly("maven.modrinth:lithium:${project.leetheum_version}")

    // Additional Entity Attributes
    modImplementation ("maven.modrinth:additionalentityattributes:${project.aea_version}")
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
}

java {
    withSourcesJar()
}

loom {
    accessWidenerPath = file("src/main/resources/mythicmetals-decorations.accesswidener")
}

jar {
    from("LICENSE")
}

fabricApi {
    configureDataGeneration {
        // Set the mod ID so that I won't lose the 50/50 to Alloy Frogery, which throws all the data into the bin
        modId = project.archives_base_name
    }
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            // add all the jars that should be included when publishing to maven
            artifact(remapJar) {
                builtBy remapJar
            }
            artifact(sourcesJar) {
                builtBy remapSourcesJar
            }
        }
    }
}

allprojects {
    gradle.projectsEvaluated {
        tasks.withType(JavaCompile) {
            options.compilerArgs << "-Xmaxerrs" << "1000"
        }
    }
}