build.gradle

plugins {
	id "architectury-plugin" version "3.1-SNAPSHOT"
	id "dev.architectury.loom" version "0.7.3-SNAPSHOT" apply false
	id "io.github.juuxel.loom-quiltflower" version "1.1.1" apply false
}

architectury {
	minecraft = rootProject.minecraft_version
}

subprojects {
	apply plugin: "dev.architectury.loom"
	apply plugin: "io.github.juuxel.loom-quiltflower"

	loom {
		silentMojangMappingsLicense()
		useFabricMixin = true
	}

	dependencies {
		minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
		mappings loom.officialMojangMappings()
	}
}

allprojects {
	apply plugin: "java"
	apply plugin: "architectury-plugin"
	apply plugin: "maven-publish"
	apply from: "https://files.latmod.com/public/markdown-git-changelog.gradle"

	def ENV = System.getenv()
	version = "${mod_version}-build.${ENV.GITHUB_RUN_NUMBER ?: 9999}"
	group = project.mod_package
	archivesBaseName = project.mod_name

	sourceCompatibility = targetCompatibility = compileJava.sourceCompatibility = compileJava.targetCompatibility = '1.8'

	configurations {
		modOptional
		modCompileOnly.extendsFrom(modOptional)
		modRuntime.extendsFrom(modOptional)

		optional
		compileOnly.extendsFrom(optional)
		runtime.extendsFrom(optional)
	}

	tasks.withType(JavaCompile) {
		options.encoding = "UTF-8"

		// The Minecraft launcher currently installs Java 8 for users, so your mod probably wants to target Java 8 too
		// JDK 9 introduced a new way of specifying this that will make sure no newer classes or methods are used.
		// We'll use that if it's available, but otherwise we'll use the older option.
		def targetVersion = 8
		if (JavaVersion.current().isJava9Compatible()) {
			options.release = targetVersion
		}
	}

	java {
		withSourcesJar()
	}

	repositories {
		maven {
			url "https://maven.architectury.dev/"
		}

		maven {
			url "https://www.cursemaven.com"
			content {
				includeGroup "curse.maven"
			}
		}

		maven {
			url "https://maven.saps.dev/minecraft"
			content {
				includeGroup "dev.latvian.mods"
				includeGroup "dev.ftb.mods"
			}
		}
	}
}

task curseforgePublish