build.gradle

plugins {
    id 'java'
    id "com.github.johnrengelman.shadow" version "7.1.0"
}

group = 'dev.rollczi'
version = '1.0.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven { url'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' }
    maven { url 'https://repo.bg-software.com/repository/api/' }
    maven { url "https://repo.panda-lang.org/releases" }
}

dependencies {
    compileOnly 'org.spigotmc:spigot-api:1.18.1-R0.1-SNAPSHOT'
    compileOnly 'com.bgsoftware:SuperiorSkyblockAPI:1.8.3'

    implementation "org.panda-lang:expressible:1.1.12"
    implementation 'net.dzikoysk:cdn:1.13.5'
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}


shadowJar {
    archiveFileName = "SkyMob v${project.version} (MC 1.8-1.18).jar"

    exclude "org/intellij/lang/annotations/**"
    exclude "org/jetbrains/annotations/**"
    exclude "javax/**"

    relocate "net.dzikoysk", "dev.rollczi.skymob.libs.net.dzikoysk"
    relocate "panda", "dev.rollczi.skymob.libs.panda"
}