build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '2.0.0'
    id 'java-gradle-plugin'
    id "com.gradle.plugin-publish" version '1.2.1'
}

group 'world.betterme.localizer'
version '1.1.0'

repositories {
    mavenCentral()
}

ext {
    kotlinVer = '2.0.0'
    gsonVer = '2.11.0'
    okHttpVer = '4.12.0'
    jupiterVer = '5.10.3'
    assertJVer = '3.26.0'
}

dependencies {
    compileOnly gradleApi()

    // Kotlin
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlinVer"

    // JSON Parsing
    implementation "com.google.code.gson:gson:$gsonVer"

    // OkHttp
    implementation "com.squareup.okhttp3:okhttp:$okHttpVer"

    // Unit-tests
    testImplementation "org.junit.jupiter:junit-jupiter-api:$jupiterVer"
    testImplementation "org.junit.jupiter:junit-jupiter-params:$jupiterVer"
    testImplementation "org.junit.jupiter:junit-jupiter-engine:$jupiterVer"
    testImplementation "org.assertj:assertj-core:$assertJVer"
}

gradlePlugin {
    website = 'https://github.com/betterme-dev/Localizer-Android'
    vcsUrl = 'https://github.com/betterme-dev/Localizer-Android'
    plugins {
        localizer {
            id = 'world.betterme.localizer'
            displayName = 'localizer'
            description = 'Gradle plugin which simplifies Android string resources & translations synchronization with POEditor. ' +
                    'More modern version of (com.betterme.localizer) which is no longer supported.'
            tags = ['translations', 'strings', 'android', 'resources', 'localization', 'poeditor']
            implementationClass = 'world.betterme.localizer.LocalizerPlugin'
        }
    }
}

test {
    useJUnitPlatform()
}

wrapper {
    gradleVersion = '8.8'
}