build.gradle

/*
 * Copyright 2016 Steven Myers
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import org.apache.tools.ant.filters.ReplaceTokens

buildscript {
    repositories {
        mavenCentral()

        // for gitsemver plugin
        maven {
            url "http://dl.bintray.com/palantir/releases"
        }
    }
    dependencies {
        classpath 'com.palantir:gradle-gitsemver:0.6.0'
        classpath("org.springframework.boot:spring-boot-gradle-plugin:1.5.1.RELEASE")
        classpath('se.transmode.gradle:gradle-docker:1.2')
    }
}

plugins {
    id 'org.springframework.boot' version '1.5.1.RELEASE'
    id 'java'
}

apply plugin: 'gitsemver'
apply plugin: 'docker'


repositories {
    mavenCentral()
}

version semverVersion()

def semver = semverVersion().toString()

jar {
    baseName = 'bytabit-server'
    version = semver
}

processResources {
    filesMatching("Dockerfile") {
        filter ReplaceTokens, tokens: [VERSION: semver]
    }
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

dependencies {
    compile 'org.springframework.boot:spring-boot-starter-web'
    compile 'org.springframework.boot:spring-boot-starter-actuator'
    compile 'org.springframework.boot:spring-boot-starter-data-jpa'
    compile 'org.postgresql:postgresql'
    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310'
    compile 'org.projectlombok:lombok:1.16.16'
    testCompile 'org.springframework.boot:spring-boot-starter-test'
}

group = 'bytabit'

task buildDocker(type: Docker, dependsOn: build) {
    push = false
    applicationName = jar.baseName
    dockerfile = file('src/main/docker/Dockerfile')
    doFirst {
        copy {
            from jar
            into stageDir
        }
    }
}

def profile = "default"
if (project.hasProperty('profileName')) {
    profile = profileName
}
bootRun {
    args = ["--spring.profiles.active="+profile]
}