build.gradle

plugins {
    id 'java'
    id 'com.google.osdetector' version '1.7.0'
    id "com.github.johnrengelman.shadow" version "7.1.2"
    id 'application'
}

mainClassName = 'net.darktree.warzone.Main'
group 'net.darktree'
version '1.0'

import org.gradle.internal.os.OperatingSystem

project.ext.lwjglVersion = "3.3.1"

switch (OperatingSystem.current()) {
    case OperatingSystem.LINUX:
        project.ext.lwjglNatives = "natives-linux"
        break
    case OperatingSystem.WINDOWS:
        project.ext.lwjglNatives = "natives-windows"
        break
}

repositories {
    mavenCentral()

    maven {
        url 'https://jitpack.io/'
    }
}

dependencies {
    implementation platform("org.lwjgl:lwjgl-bom:$lwjglVersion")

    implementation "org.lwjgl:lwjgl"
    implementation "org.lwjgl:lwjgl-assimp"
    implementation "org.lwjgl:lwjgl-glfw"
    implementation "org.lwjgl:lwjgl-openal"
    implementation "org.lwjgl:lwjgl-opengl"
    implementation "org.lwjgl:lwjgl-stb"
    runtimeOnly "org.lwjgl:lwjgl::$lwjglNatives"
    runtimeOnly "org.lwjgl:lwjgl-assimp::$lwjglNatives"
    runtimeOnly "org.lwjgl:lwjgl-glfw::$lwjglNatives"
    runtimeOnly "org.lwjgl:lwjgl-openal::$lwjglNatives"
    runtimeOnly "org.lwjgl:lwjgl-opengl::$lwjglNatives"
    runtimeOnly "org.lwjgl:lwjgl-stb::$lwjglNatives"

    implementation 'com.github.Querz:NBT:6.1'
    implementation 'org.jetbrains:annotations:20.1.0'
    implementation 'com.google.code.gson:gson:2.9.0'
    implementation 'com.google.guava:guava:31.1-jre'

    implementation('io.netty:netty-all:4.1.64.Final') {
        exclude group: 'io.netty', module: 'netty-tcnative'
    }
    //implementation 'io.netty:netty-tcnative:2.0.39.Final:' + osdetector.classifier

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.8.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.8.2'
}

test {
    useJUnitPlatform()
}

run {
    File runDirectory = new File('build/run/')
    runDirectory.mkdirs()

    workingDir = runDirectory
    standardInput = System.in
}

jar {
    manifest {
        attributes 'Main-Class': mainClassName
        attributes 'Application-Version': archiveVersion.get()
    }
}