-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathKeyExchange.ec
5964 lines (5651 loc) · 196 KB
/
KeyExchange.ec
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* KeyExchange.ec *)
(* Diffie-Hellman Key Exchange *)
prover quorum=2 ["Alt-Ergo" "Z3"].
require import AllCore List FSet SmtMap Distr ListAux ListPO.
require import UCCoreDiffieHellman.
require Forward RedundantHashing.
(* theory parameters *)
(* port index of adversary that forwarding functionalities communicate
with *)
op adv_fw_pi : int.
(* port index of adversary for key exchange simulator *)
op ke_sim_adv_pi : int.
axiom ke_pi_uniq : uniq [ke_sim_adv_pi; adv_fw_pi; 0].
(* end theory parameters *)
(* request sent to port index 1 of key exchange functionality: pt1
wants to exchange a key with pt2 *)
op ke_req1 (func : addr, pt1 pt2 : port) : msg =
(Dir, (func, 1), pt1, UnivPort pt2).
op dec_ke_req1 (m : msg) : (addr * port * port) option =
let (mod, pt1, pt2, v) = m
in (mod = Adv \/ pt1.`2 <> 1 \/ ! is_univ_port v) ?
None :
Some (pt1.`1, pt2, oget (dec_univ_port v)).
lemma enc_dec_ke_req1 (func : addr, pt1 pt2 : port) :
dec_ke_req1 (ke_req1 func pt1 pt2) = Some (func, pt1, pt2).
proof. done. qed.
lemma dec_enc_ke_req1 (m : msg, func : addr, pt1 pt2 : port) :
dec_ke_req1 m = Some (func, pt1, pt2) =>
ke_req1 func pt1 pt2 = m.
proof.
case m => mod pt1' pt2' u'.
rewrite /dec_ke_req1 /ke_req1 /=.
case (mod = Adv \/ pt1'.`2 <> 1 \/ ! is_univ_port u') => //.
rewrite !negb_or /= not_adv.
move => [#] -> pt1'_2 iupt_u'.
have [] pt2'' : exists (pt2'' : port), dec_univ_port u' = Some pt2''.
exists (oget (dec_univ_port u')); by rewrite -some_oget.
move => /dec_enc_univ_port -> /=.
smt().
qed.
op is_ke_req1 (m : msg) : bool =
dec_ke_req1 m <> None.
lemma is_ke_req1 (func : addr, pt1 pt2 : port) :
is_ke_req1 (ke_req1 func pt1 pt2).
proof. done. qed.
(* response sent from port index 2 of key exchange functionality to
pt2, completing first phase of key exchange initiated by pt1 *)
op ke_rsp1 (func : addr, pt1 pt2 : port, x : key) : msg =
(Dir, pt2, (func, 2), UnivPair (UnivPort pt1, UnivBase (BaseKey x))).
op dec_ke_rsp1 (m : msg) : (addr * port * port * key) option =
let (mod, pt1, pt2, v) = m
in (mod = Adv \/ pt2.`2 <> 2 \/ ! is_univ_pair v) ?
None :
let (v1, v2) = oget (dec_univ_pair v)
in (! is_univ_port v1 \/ ! is_univ_base v2) ?
None :
let b = oget (dec_univ_base v2)
in (! is_base_key b) ?
None :
Some (pt2.`1, oget (dec_univ_port v1), pt1,
oget (dec_base_key b)).
lemma enc_dec_ke_rsp1 (func : addr, pt1 pt2 : port, x : key) :
dec_ke_rsp1 (ke_rsp1 func pt1 pt2 x) = Some (func, pt1, pt2, x).
proof.
by rewrite /ke_rsp1 /dec_ke_rsp1 /=
(is_univ_pair (UnivPort pt1, UnivBase (BaseKey x))).
qed.
lemma dec_enc_ke_rsp1 (m : msg, func : addr, pt1 pt2 : port, k : key) :
dec_ke_rsp1 m = Some (func, pt1, pt2, k) =>
ke_rsp1 func pt1 pt2 k = m.
proof.
case m => mod pt1' pt2' u'.
rewrite /dec_ke_rsp1 /ke_rsp1 /=.
case (mod = Adv \/ pt2'.`2 <> 2 \/ ! is_univ_pair u') => //.
rewrite !negb_or /= not_adv.
move => [#] -> pt2'_2 iup_u'.
have [] p : exists (p : univ * univ), dec_univ_pair u' = Some p.
exists (oget (dec_univ_pair u')); by rewrite -some_oget.
case p => v1 v2 /dec_enc_univ_pair -> /=.
case (! is_univ_port v1 \/ ! is_univ_base v2) => //.
rewrite !negb_or /=.
move => [#] iupt_v1 iub_v2.
case (! is_base_key (oget (dec_univ_base v2))) => //=.
have [] pt' : exists (pt' : port), dec_univ_port v1 = Some pt'.
exists (oget (dec_univ_port v1)); by rewrite -some_oget.
move => /dec_enc_univ_port -> /=.
have [] bse : exists (bse : base), dec_univ_base v2 = Some bse.
exists (oget (dec_univ_base v2)); by rewrite -some_oget.
move => /dec_enc_univ_base -> /=.
move => ibk_bse.
have [] k' : exists (k' : key), dec_base_key bse = Some k'.
exists (oget (dec_base_key bse)); by rewrite -some_oget.
move => /dec_enc_base_key -> /=.
smt().
qed.
op is_ke_rsp1 (m : msg) : bool =
dec_ke_rsp1 m <> None.
lemma is_ke_rsp1 (func : addr, pt1 pt2 : port, x : key) :
is_ke_rsp1 (ke_rsp1 func pt1 pt2 x).
proof.
by rewrite /is_ke_rsp1 enc_dec_ke_rsp1.
qed.
lemma dest_good_ke_rsp1 (m : msg) :
is_ke_rsp1 m => (oget (dec_ke_rsp1 m)).`3 = m.`2.
proof.
move => is_ke_rsp1_m.
have [] x : exists (x : addr * port * port * key),
dec_ke_rsp1 m = Some x.
exists (oget (dec_ke_rsp1 m)); by rewrite -some_oget.
case x => x1 x2 x3 x4 /dec_enc_ke_rsp1 <-.
by rewrite enc_dec_ke_rsp1 /ke_rsp1.
qed.
(* request sent to port index 2 of key exchange functionality by pt2 to
initiate phase 2 of key exchange with pt1 *)
op ke_req2 (func : addr, pt2 : port) : msg =
(Dir, (func, 2), pt2, UnivUnit).
op dec_ke_req2 (m : msg) : (addr * port) option =
let (mod, pt1, pt2, v) = m
in (mod = Adv \/ pt1.`2 <> 2 \/ v <> UnivUnit) ?
None :
Some (pt1.`1, pt2).
lemma enc_dec_ke_req2 (func : addr, pt2 : port) :
dec_ke_req2 (ke_req2 func pt2) = Some (func, pt2).
proof. done. qed.
lemma dec_enc_ke_req2 (m : msg, func : addr, pt2 : port) :
dec_ke_req2 m = Some (func, pt2) =>
ke_req2 func pt2 = m.
proof.
case m => mod pt1' pt2' u'.
rewrite /dec_ke_req2 /ke_req2 /=.
case (mod = Adv \/ pt1'.`2 <> 2 \/ u' <> UnivUnit) => //.
rewrite !negb_or /= not_adv.
move => [#] -> pt1'_2 -> /#.
qed.
op is_ke_req2 (m : msg) : bool =
dec_ke_req2 m <> None.
lemma is_ke_req2 (func : addr, pt2 : port) :
is_ke_req2 (ke_req2 func pt2).
proof. done. qed.
(* response sent from port index 1 of key exchange functionality to
pt1, completing second phase of key exchange with pt2 initiated by
itself *)
op ke_rsp2 (func : addr, pt1 : port, x : key) : msg =
(Dir, pt1, (func, 1), UnivBase (BaseKey x)).
op dec_ke_rsp2 (m : msg) : (addr * port * key) option =
let (mod, pt1, pt2, v) = m
in (mod = Adv \/ pt2.`2 <> 1 \/ ! is_univ_base v) ?
None :
let bse = oget (dec_univ_base v)
in (! is_base_key bse) ?
None :
Some (pt2.`1, pt1, oget (dec_base_key bse)).
lemma enc_dec_ke_rsp2 (func : addr, pt1 : port, k : key) :
dec_ke_rsp2 (ke_rsp2 func pt1 k) = Some (func, pt1, k).
proof.
by rewrite /ke_rsp2 /dec_ke_rsp2 /= (is_univ_base (BaseKey k)).
qed.
lemma dec_enc_ke_rsp2 (m : msg, func : addr, pt1 : port, k : key) :
dec_ke_rsp2 m = Some (func, pt1, k) =>
ke_rsp2 func pt1 k = m.
proof.
case m => mod pt1' pt2' u'.
rewrite /dec_ke_rsp2 /ke_rsp2 /=.
case (mod = Adv \/ pt2'.`2 <> 1 \/ ! is_univ_base u') => //.
rewrite !negb_or /= not_adv.
move => [#] -> pt2'_2 iup_u'.
have [] bse : exists (bse : base), dec_univ_base u' = Some bse.
exists (oget (dec_univ_base u')); by rewrite -some_oget.
move => /dec_enc_univ_base ->.
case (! is_base_key (oget (dec_univ_base (UnivBase bse)))) => //=.
move => ibk_bse.
have [] k' : exists (k' : key), dec_base_key bse = Some k'.
exists (oget (dec_base_key bse)); by rewrite -some_oget.
move => /dec_enc_base_key -> /#.
qed.
op is_ke_rsp2 (m : msg) : bool =
dec_ke_rsp2 m <> None.
lemma is_ke_rsp2 (func : addr, pt1 : port, x : key) :
is_ke_rsp2 (ke_rsp2 func pt1 x).
proof.
by rewrite /is_ke_rsp2 enc_dec_ke_rsp2.
qed.
lemma dest_good_ke_rsp2 (m : msg) :
is_ke_rsp2 m => (oget (dec_ke_rsp2 m)).`2 = m.`2.
proof.
move => is_ke_rsp2_m.
have [] x : exists (x : addr * port * key), dec_ke_rsp2 m = Some x.
exists (oget (dec_ke_rsp2 m)); by rewrite -some_oget.
case x => x1 x2 x3 /dec_enc_ke_rsp2 <-.
by rewrite enc_dec_ke_rsp2 /ke_rsp2.
qed.
(* Real Functionality *)
clone Forward as Fwd1
with op adv_pi <- adv_fw_pi
proof *.
realize fwd_pi_uniq. by have := ke_pi_uniq. qed.
clone Forward as Fwd2
with op adv_pi <- adv_fw_pi
proof *.
realize fwd_pi_uniq. by have := ke_pi_uniq. qed.
(* state for Party 1 *)
type ke_real_p1_state = [
KERealP1StateWaitReq1
| KERealP1StateWaitFwd2 of (port * port * exp)
| KERealP1StateFinal of (port * port * exp)
].
op dec_ke_real_p1_state_wait_fwd2 (st : ke_real_p1_state) :
(port * port * exp) option =
with st = KERealP1StateWaitReq1 => None
with st = KERealP1StateWaitFwd2 x => Some x
with st = KERealP1StateFinal _ => None.
lemma enc_dec_ke_real_p1_state_wait_fwd2 (x : port * port * exp) :
dec_ke_real_p1_state_wait_fwd2 (KERealP1StateWaitFwd2 x) = Some x.
proof. done. qed.
op is_ke_real_p1_state_wait_fwd2 (st : ke_real_p1_state) : bool =
dec_ke_real_p1_state_wait_fwd2 st <> None.
lemma is_ke_real_p1_state_wait_fwd2 (x : port * port * exp) :
is_ke_real_p1_state_wait_fwd2 (KERealP1StateWaitFwd2 x).
proof. done. qed.
op dec_ke_real_p1_state_final (st : ke_real_p1_state) :
(port * port * exp) option =
with st = KERealP1StateWaitReq1 => None
with st = KERealP1StateWaitFwd2 _ => None
with st = KERealP1StateFinal x => Some x.
lemma enc_dec_ke_real_p1_state_final (x : port * port * exp) :
dec_ke_real_p1_state_final (KERealP1StateFinal x) = Some x.
proof. done. qed.
op is_ke_real_p1_state_final (st : ke_real_p1_state) : bool =
dec_ke_real_p1_state_final st <> None.
lemma is_ke_real_p1_state_final (x : port * port * exp) :
is_ke_real_p1_state_final (KERealP1StateFinal x).
proof. done. qed.
(* state for Party 2 *)
type ke_real_p2_state = [
KERealP2StateWaitFwd1
| KERealP2StateWaitReq2 of (port * port * exp)
| KERealP2StateFinal of (port * port * exp)
].
op dec_ke_real_p2_state_wait_req2 (st : ke_real_p2_state) :
(port * port * exp) option =
with st = KERealP2StateWaitFwd1 => None
with st = KERealP2StateWaitReq2 x => Some x
with st = KERealP2StateFinal _ => None.
lemma enc_dec_ke_real_p2_state_wait_req2 (x : port * port * exp) :
dec_ke_real_p2_state_wait_req2 (KERealP2StateWaitReq2 x) = Some x.
proof. done. qed.
op is_ke_real_p2_state_wait_req2 (st : ke_real_p2_state) : bool =
dec_ke_real_p2_state_wait_req2 st <> None.
lemma is_ke_real_p2_state_wait_req2 (x : port * port * exp) :
is_ke_real_p2_state_wait_req2 (KERealP2StateWaitReq2 x).
proof. done. qed.
op dec_ke_real_p2_state_final (st : ke_real_p2_state) :
(port * port * exp) option =
with st = KERealP2StateWaitFwd1 => None
with st = KERealP2StateWaitReq2 _ => None
with st = KERealP2StateFinal x => Some x.
lemma enc_dec_ke_real_p2_state_final (x : port * port * exp) :
dec_ke_real_p2_state_final (KERealP2StateFinal x) = Some x.
proof. done. qed.
op is_ke_real_p2_state_final (st : ke_real_p2_state) : bool =
dec_ke_real_p2_state_final st <> None.
lemma is_ke_real_p2_state_final (x : port * port * exp) :
is_ke_real_p2_state_final (KERealP2StateFinal x).
proof. done. qed.
module KEReal : FUNC = {
var self, adv : addr
var st1 : ke_real_p1_state
var st2 : ke_real_p2_state
(* Party 1 (P1) manages ports (self, 1) and (self, 3)
Party 2 (P2) manages ports (self, 2) and (self, 4)
First forwarder (Fwd1) is at address self ++ [1]
Second forwarder (Fwd2) is at address self ++ [2] *)
proc init(self_ adv_ : addr) : unit = {
self <- self_; adv <- adv_;
Fwd1.Forw.init(self ++ [1], adv); Fwd2.Forw.init(self ++ [2], adv);
st1 <- KERealP1StateWaitReq1; st2 <- KERealP2StateWaitFwd1;
}
proc party1(m : msg) : msg option = {
var pt1, pt2, pt1', pt2' : port; var addr : addr;
var u : univ; var k2 : key; var q1 : exp;
var r : msg option <- None;
if (st1 = KERealP1StateWaitReq1) {
if (is_ke_req1 m) {
(* destination of m is (self, 1) *)
(addr, pt1, pt2) <- oget (dec_ke_req1 m);
if (! self <= pt1.`1 /\ ! self <= pt2.`1 /\
! adv <= pt1.`1 /\ ! adv <= pt2.`1) {
q1 <$ dexp;
r <-
Some
(Fwd1.fw_req
(self ++ [1]) (self, 3) (self, 4)
(univ_triple (UnivPort pt1) (UnivPort pt2)
(UnivBase (BaseKey (g ^ q1)))));
st1 <- KERealP1StateWaitFwd2 (pt1, pt2, q1);
}
}
}
elif (is_ke_real_p1_state_wait_fwd2 st1) {
(pt1, pt2, q1) <- oget (dec_ke_real_p1_state_wait_fwd2 st1);
if (Fwd2.is_fw_rsp m) {
(addr, pt1', pt2', u) <- oget (Fwd2.dec_fw_rsp m);
if (pt2' = (self, 3)) {
(* destination of m is (self, 3) *)
k2 <- oget (dec_base_key (oget (dec_univ_base u)));
r <- Some (ke_rsp2 self pt1 (k2 ^ q1));
st1 <- KERealP1StateFinal (pt1, pt2, q1);
}
}
}
else { (* is_ke_real_p1_state_final st1 *)
}
return r;
}
proc party2(m : msg) : msg option = {
var pt1, pt2, pt1', pt2' : port; var addr : addr;
var u, v1, v2, v3 : univ; var k1 : key; var q2 : exp;
var r : msg option <- None;
if (st2 = KERealP2StateWaitFwd1) {
if (Fwd1.is_fw_rsp m) {
(addr, pt1', pt2', u) <- oget (Fwd1.dec_fw_rsp m);
if (pt2' = (self, 4)) {
(* destination of m is (self, 4) *)
(v1, v2, v3) <- oget (dec_univ_triple u);
pt1 <- oget (dec_univ_port v1);
pt2 <- oget (dec_univ_port v2);
k1 <- oget (dec_base_key (oget (dec_univ_base v3)));
q2 <$ dexp;
r <- Some (ke_rsp1 self pt1 pt2 (k1 ^ q2));
st2 <- KERealP2StateWaitReq2 (pt1, pt2, q2);
}
}
}
elif (is_ke_real_p2_state_wait_req2 st2) {
(pt1, pt2, q2) <- oget (dec_ke_real_p2_state_wait_req2 st2);
if (is_ke_req2 m) {
(* destination of m is (self, 2) *)
(addr, pt2') <- oget (dec_ke_req2 m);
if (pt2' = pt2) {
r <-
Some
(Fwd2.fw_req
(self ++ [2]) (self, 4) (self, 3)
(UnivBase (BaseKey (g ^ q2))));
st2 <- KERealP2StateFinal (pt1, pt2, q2);
}
}
}
else { (* is_ke_real_p2_state_final st2 *)
}
return r;
}
proc loop(m : msg) : msg option = {
var r : msg option <- None;
var not_done : bool <- true;
(* invariant:
not_done =>
m.`2.`1 = self /\
(m.`2.`2 = 1 \/ m.`2.`2 = 2 \/
m.`2.`2 = 3 \/ m.`2.`2 = 4) \/
self ++ [1] <= m.`2.`1 \/
self ++ [2] <= m.`2.`1 *)
while (not_done) {
if (m.`2.`1 = self /\ (m.`2.`2 = 1 \/ m.`2.`2 = 3)) {
r <@ party1(m);
}
elif (m.`2.`1 = self /\ (m.`2.`2 = 2 \/ m.`2.`2 = 4)) {
r <@ party2(m);
}
elif (self ++ [1] <= m.`2.`1) {
r <@ Fwd1.Forw.invoke(m);
}
else { (* self ++ [2] <= m.`2.`1 *)
r <@ Fwd2.Forw.invoke(m);
}
if (r = None \/ ! self <= (oget r).`2.`1) {
not_done <- false;
}
else {
m <- oget r;
}
}
return r;
}
proc invoke(m : msg) : msg option = {
var mod : mode; var pt1, pt2 : port; var u : univ;
var addr1 : addr; var n1 : int;
var r : msg option <- None;
(mod, pt1, pt2, u) <- m; (addr1, n1) <- pt1;
if ((mod = Dir /\ addr1 = self /\ (n1 = 1 \/ n1 = 2)) \/
(mod = Adv /\ (self ++ [1] <= addr1 \/ self ++ [2] <= addr1))) {
r <@ loop(m);
}
return r;
}
}.
lemma ke_real_init :
equiv
[KEReal.init ~ KEReal.init :
={self_, adv_} ==> ={res, glob KEReal}].
proof.
proc.
swap [5..6] -2.
call Fwd2.init.
call Fwd1.init.
auto.
qed.
(* Ideal Functionality *)
(* request sent from port index 3 of key exchange ideal functionality
to port index ke_sim_adv_pi of key exchange simulator, initiating
first phase of execution of simulator *)
op ke_sim_req1 (ideal adv : addr, pt1 pt2 : port) : msg =
(Adv, (adv, ke_sim_adv_pi), (ideal, 3),
UnivPair (UnivPort pt1, UnivPort pt2)).
op dec_ke_sim_req1 (m : msg) : (addr * addr * port * port) option =
let (mod, pt1, pt2, v) = m
in (mod = Dir \/ pt1.`2 <> ke_sim_adv_pi \/ pt2.`2 <> 3 \/
! is_univ_pair v) ?
None :
let (v1, v2) = oget (dec_univ_pair v)
in (! is_univ_port v1 \/ ! is_univ_port v2) ?
None :
Some (pt2.`1, pt1.`1,
oget (dec_univ_port v1), oget (dec_univ_port v2)).
lemma enc_dec_ke_sim_req1 (ideal adv : addr, pt1 pt2 : port) :
dec_ke_sim_req1 (ke_sim_req1 ideal adv pt1 pt2) =
Some (ideal, adv, pt1, pt2).
proof. done. qed.
lemma dec_enc_ke_sim_req1 (m : msg, ideal adv : addr, pt1 pt2 : port) :
dec_ke_sim_req1 m = Some (ideal, adv, pt1, pt2) =>
ke_sim_req1 ideal adv pt1 pt2 = m.
proof.
case m => mod pt1' pt2' u'.
rewrite /dec_ke_sim_req1 /ke_sim_req1 /=.
case (mod = Dir \/ pt1'.`2 <> ke_sim_adv_pi \/ pt2'.`2 <> 3 \/
! is_univ_pair u') => //.
rewrite !negb_or /= not_dir.
move => [#] -> pt1'_2 pt2'_2 iupt_u'.
have [] p : exists (p : univ * univ), dec_univ_pair u' = Some p.
exists (oget (dec_univ_pair u')); by rewrite -some_oget.
case p => v1 v2 /dec_enc_univ_pair -> /=.
case (! is_univ_port v1 \/ ! is_univ_port v2) => //.
rewrite !negb_or /=.
move => [#] iupt_v1 iupt_v2.
have [] pt1'' : exists (pt1'' : port), dec_univ_port v1 = Some pt1''.
exists (oget (dec_univ_port v1)); by rewrite -some_oget.
move => /dec_enc_univ_port ->.
have [] pt2'' : exists (pt2'' : port), dec_univ_port v2 = Some pt2''.
exists (oget (dec_univ_port v2)); by rewrite -some_oget.
move => /dec_enc_univ_port -> /> /#.
qed.
op is_ke_sim_req1 (m : msg) : bool =
dec_ke_sim_req1 m <> None.
lemma is_ke_sim_req1 (ideal adv : addr, pt1 pt2 : port) :
is_ke_sim_req1 (ke_sim_req1 ideal adv pt1 pt2).
proof. done. qed.
(* response sent from port ke_sim_adv_pi of key exchange simulator to
port 3 of key exchange ideal functionality, completing first or
second phase of simulator execution *)
op ke_sim_rsp (ideal adv : addr) : msg =
(Adv, (ideal, 3), (adv, ke_sim_adv_pi), UnivUnit).
op dec_ke_sim_rsp (m : msg) : (addr * addr) option =
let (mod, pt1, pt2, v) = m
in (mod = Dir \/ pt1.`2 <> 3 \/ pt2.`2 <> ke_sim_adv_pi \/
! v = UnivUnit) ?
None :
Some (pt1.`1, pt2.`1).
lemma enc_dec_ke_sim_rsp (ideal adv : addr) :
dec_ke_sim_rsp (ke_sim_rsp ideal adv) = Some (ideal, adv).
proof. done. qed.
lemma dec_enc_ke_sim_rsp (m : msg, ideal adv : addr) :
dec_ke_sim_rsp m = Some (ideal, adv) =>
ke_sim_rsp ideal adv = m.
proof.
case m => mod pt1' pt2' u'.
rewrite /dec_ke_sim_rsp /ke_sim_rsp /=.
case (mod = Dir \/ pt1'.`2 <> 3 \/ pt2'.`2 <> ke_sim_adv_pi \/
u' <> UnivUnit) => //.
rewrite !negb_or /= not_dir.
move => [#] -> pt1'_2 pt2'_2 iupt_u' [#] /#.
qed.
op is_ke_sim_rsp (m : msg) : bool =
dec_ke_sim_rsp m <> None.
lemma is_ke_sim_rsp (ideal adv : addr) :
is_ke_sim_rsp (ke_sim_rsp ideal adv).
proof. done. qed.
lemma dest_good_ke_sim_rsp (m : msg) :
is_ke_sim_rsp m => (oget (dec_ke_sim_rsp m)).`1 = m.`2.`1.
proof.
move => is_ke_sim_rsp_m.
have [] p : exists (p : addr * addr), dec_ke_sim_rsp m = Some p.
exists (oget (dec_ke_sim_rsp m)); by rewrite -some_oget.
case p => ideal adv /dec_enc_ke_sim_rsp <-.
by rewrite enc_dec_ke_sim_rsp /ke_sim_rsp.
qed.
lemma port_good_ke_sim_rsp (m : msg) :
is_ke_sim_rsp m => m.`2.`2 = 3.
proof.
move => is_ke_sim_rsp_m.
have [] p : exists (p : addr * addr), dec_ke_sim_rsp m = Some p.
exists (oget (dec_ke_sim_rsp m)); by rewrite -some_oget.
case p => ideal adv /dec_enc_ke_sim_rsp <-.
by rewrite /ke_sim_rsp.
qed.
(* request sent from port 3 of key exchange ideal functionality to
port ke_sim_adv_pi of key exchange simulator, initiating second phase
of execution of simulator *)
op ke_sim_req2 (ideal adv : addr) : msg =
(Adv, (adv, ke_sim_adv_pi), (ideal, 3), UnivUnit).
op dec_ke_sim_req2 (m : msg) : (addr * addr) option =
let (mod, pt1, pt2, v) = m
in (mod = Dir \/ pt1.`2 <> ke_sim_adv_pi \/ pt2.`2 <> 3 \/
! v = UnivUnit) ?
None :
Some (pt2.`1, pt1.`1).
lemma enc_dec_ke_sim_req2 (ideal adv : addr) :
dec_ke_sim_req2 (ke_sim_req2 ideal adv) = Some (ideal, adv).
proof. done. qed.
lemma dec_enc_ke_sim_req2 (m : msg, ideal adv : addr) :
dec_ke_sim_req2 m = Some (ideal, adv) =>
ke_sim_req2 ideal adv = m.
proof.
case m => mod pt1' pt2' u'.
rewrite /dec_ke_sim_req2 /ke_sim_req2 /=.
case (mod = Dir \/ pt1'.`2 <> ke_sim_adv_pi \/ pt2'.`2 <> 3 \/
u' <> UnivUnit) => //.
rewrite !negb_or /= not_dir.
move => [#] -> pt1'_2 pt2'_2 -> /#.
qed.
op is_ke_sim_req2 (m : msg) : bool =
dec_ke_sim_req2 m <> None.
lemma is_ke_sim_req2 (ideal adv : addr) :
is_ke_sim_req2 (ke_sim_req2 ideal adv).
proof. done. qed.
type ke_ideal_state = [
KEIdealStateWaitReq1
| KEIdealStateWaitSim1 of (port * port)
| KEIdealStateWaitReq2 of (port * port * exp)
| KEIdealStateWaitSim2 of (port * port * exp)
| KEIdealStateFinal of (port * port * exp)
].
op dec_ke_ideal_state_wait_sim1 (st : ke_ideal_state) :
(port * port) option =
with st = KEIdealStateWaitReq1 => None
with st = KEIdealStateWaitSim1 x => Some x
with st = KEIdealStateWaitReq2 _ => None
with st = KEIdealStateWaitSim2 _ => None
with st = KEIdealStateFinal _ => None.
lemma enc_dec_ke_ideal_state_wait_sim1 (x : port * port) :
dec_ke_ideal_state_wait_sim1 (KEIdealStateWaitSim1 x) = Some x.
proof. done. qed.
op is_ke_ideal_state_wait_sim1 (st : ke_ideal_state) : bool =
dec_ke_ideal_state_wait_sim1 st <> None.
lemma is_ke_ideal_state_wait_sim1 (x : port * port) :
is_ke_ideal_state_wait_sim1 (KEIdealStateWaitSim1 x).
proof. done. qed.
op dec_ke_ideal_state_wait_req2 (st : ke_ideal_state) :
(port * port * exp) option =
with st = KEIdealStateWaitReq1 => None
with st = KEIdealStateWaitSim1 _ => None
with st = KEIdealStateWaitReq2 x => Some x
with st = KEIdealStateWaitSim2 _ => None
with st = KEIdealStateFinal _ => None.
lemma enc_dec_ke_ideal_state_wait_req2 (x : port * port * exp) :
dec_ke_ideal_state_wait_req2 (KEIdealStateWaitReq2 x) = Some x.
proof. done. qed.
op is_ke_ideal_state_wait_req2 (st : ke_ideal_state) : bool =
dec_ke_ideal_state_wait_req2 st <> None.
lemma is_ke_ideal_state_wait_req2 (x : port * port * exp) :
is_ke_ideal_state_wait_req2 (KEIdealStateWaitReq2 x).
proof. done. qed.
op dec_ke_ideal_state_wait_sim2 (st : ke_ideal_state) :
(port * port * exp) option =
with st = KEIdealStateWaitReq1 => None
with st = KEIdealStateWaitSim1 _ => None
with st = KEIdealStateWaitReq2 _ => None
with st = KEIdealStateWaitSim2 x => Some x
with st = KEIdealStateFinal _ => None.
lemma enc_dec_ke_ideal_state_wait_sim2 (x : port * port * exp) :
dec_ke_ideal_state_wait_sim2 (KEIdealStateWaitSim2 x) = Some x.
proof. done. qed.
op is_ke_ideal_state_wait_sim2 (st : ke_ideal_state) : bool =
dec_ke_ideal_state_wait_sim2 st <> None.
lemma is_ke_ideal_state_wait_sim2 (x : port * port * exp) :
is_ke_ideal_state_wait_sim2 (KEIdealStateWaitSim2 x).
proof. done. qed.
op dec_ke_ideal_state_final (st : ke_ideal_state) :
(port * port * exp) option =
with st = KEIdealStateWaitReq1 => None
with st = KEIdealStateWaitSim1 _ => None
with st = KEIdealStateWaitReq2 _ => None
with st = KEIdealStateWaitSim2 _ => None
with st = KEIdealStateFinal x => Some x.
lemma enc_dec_ke_ideal_state_final (x : port * port * exp) :
dec_ke_ideal_state_final (KEIdealStateFinal x) = Some x.
proof. done. qed.
op is_ke_ideal_state_final (st : ke_ideal_state) : bool =
dec_ke_ideal_state_final st <> None.
lemma is_ke_ideal_state_final (x : port * port * exp) :
is_ke_ideal_state_final (KEIdealStateFinal x).
proof. done. qed.
module KEIdeal : FUNC = {
var self, adv : addr
var st : ke_ideal_state
proc init(self_ adv_ : addr) : unit = {
self <- self_; adv <- adv_;
st <- KEIdealStateWaitReq1;
}
proc parties(m : msg) : msg option = {
var pt1, pt2, pt2' : port; var addr1, addr2 : addr;
var q : exp;
var r : msg option <- None;
if (st = KEIdealStateWaitReq1) {
if (is_ke_req1 m) {
(* destination of m is (self, 1), mode of m is Dir *)
(addr1, pt1, pt2) <- oget (dec_ke_req1 m);
if (! self <= pt1.`1 /\ ! self <= pt2.`1 /\
! adv <= pt1.`1 /\ ! adv <= pt2.`1) {
r <- Some (ke_sim_req1 self adv pt1 pt2);
st <- KEIdealStateWaitSim1 (pt1, pt2);
}
}
}
elif (is_ke_ideal_state_wait_sim1 st) {
(pt1, pt2) <- oget (dec_ke_ideal_state_wait_sim1 st);
if (is_ke_sim_rsp m) {
(* destination of m is (self, 3), mode of m is Adv *)
q <$ dexp;
r <- Some (ke_rsp1 self pt1 pt2 (g ^ q));
st <- KEIdealStateWaitReq2 (pt1, pt2, q);
}
}
elif (is_ke_ideal_state_wait_req2 st) {
(pt1, pt2, q) <- oget (dec_ke_ideal_state_wait_req2 st);
if (is_ke_req2 m) {
(* destination of m is (self, 2), mode of m is Dir *)
(addr1, pt2') <- oget (dec_ke_req2 m);
if (pt2' = pt2) {
r <- Some (ke_sim_req2 self adv);
st <- KEIdealStateWaitSim2 (pt1, pt2, q);
}
}
}
elif (is_ke_ideal_state_wait_sim2 st) {
(pt1, pt2, q) <- oget (dec_ke_ideal_state_wait_sim2 st);
if (is_ke_sim_rsp m) {
(* destination of m is (self, 3), mode of m is Adv *)
r <- Some (ke_rsp2 self pt1 (g ^ q));
st <- KEIdealStateFinal (pt1, pt2, q);
}
}
else { (* is_ke_ideal_state_final st *)
}
return r;
}
proc invoke(m : msg) : msg option = {
var mod : mode; var pt1, pt2 : port; var u : univ;
var addr1, addr2 : addr; var n1, n2 : int;
var r : msg option <- None;
(mod, pt1, pt2, u) <- m;
(addr1, n1) <- pt1;
if ((mod = Dir /\ addr1 = self /\ (n1 = 1 \/ n1 = 2)) \/
(mod = Adv /\ addr1 = self /\ n1 = 3)) {
r <@ parties(m);
}
return r;
}
}.
lemma ke_ideal_init :
equiv
[KEIdeal.init ~ KEIdeal.init :
={self_, adv_} ==> ={res, glob KEIdeal}].
proof. proc; auto. qed.
(* termination metric and proof for KEIdeal *)
op ke_ideal_term_metric_max : int = 4.
op ke_ideal_term_metric (st : ke_ideal_state) : int =
with st = KEIdealStateWaitReq1 => 4
with st = KEIdealStateWaitSim1 _ => 3
with st = KEIdealStateWaitReq2 _ => 2
with st = KEIdealStateWaitSim2 _ => 1
with st = KEIdealStateFinal _ => 0.
lemma ge0_ke_ideal_term_metric (st : ke_ideal_state) :
0 <= ke_ideal_term_metric st.
proof. by case st. qed.
lemma ke_ideal_term_metric_is_ke_ideal_state_wait_sim1
(st : ke_ideal_state) :
is_ke_ideal_state_wait_sim1 st => ke_ideal_term_metric st = 3.
proof. by case st. qed.
lemma ke_ideal_term_metric_is_ke_ideal_state_wait_req2
(st : ke_ideal_state) :
is_ke_ideal_state_wait_req2 st => ke_ideal_term_metric st = 2.
proof. by case st. qed.
lemma ke_ideal_term_metric_is_ke_ideal_state_wait_sim2
(st : ke_ideal_state) :
is_ke_ideal_state_wait_sim2 st => ke_ideal_term_metric st = 1.
proof. by case st. qed.
lemma ke_ideal_term_init :
equiv
[KEIdeal.init ~ KEIdeal.init :
={self_, adv_} ==>
={res, glob KEIdeal} /\
ke_ideal_term_metric KEIdeal.st{1} = ke_ideal_term_metric_max].
proof. proc; auto. qed.
lemma ke_ideal_term_invoke (n : int) :
equiv
[KEIdeal.invoke ~ KEIdeal.invoke :
={m, glob KEIdeal} /\
ke_ideal_term_metric KEIdeal.st{1} = n ==>
={res, KEIdeal.st} /\
(res{1} = None \/ ke_ideal_term_metric KEIdeal.st{1} = n - 1)].
proof.
proc; sp 3 3.
if => //.
inline KEIdeal.parties.
sp 2 2.
if => //.
if => //.
sp 1 1.
if; first smt().
auto; smt().
auto.
auto.
if => //.
sp 1 1.
if => //.
auto; smt(ke_ideal_term_metric_is_ke_ideal_state_wait_sim1).
auto.
if => //.
sp 1 1.
if => //.
sp 1 1.
if => //.
auto; smt().
auto; smt(ke_ideal_term_metric_is_ke_ideal_state_wait_req2).
auto.
auto.
if => //.
sp 1 1.
if => //.
auto; smt(ke_ideal_term_metric_is_ke_ideal_state_wait_sim2).
auto.
auto.
qed.
(* Simulator *)
type ke_sim_state = [
KESimStateWaitReq1
| KESimStateWaitAdv1 of (addr * exp)
| KESimStateWaitReq2 of (addr * exp * exp)
| KESimStateWaitAdv2 of (addr * exp * exp)
| KESimStateFinal of (addr * exp * exp)
].
op dec_ke_sim_state_wait_adv1 (st : ke_sim_state) : (addr * exp) option =
with st = KESimStateWaitReq1 => None
with st = KESimStateWaitAdv1 x => Some x
with st = KESimStateWaitReq2 _ => None
with st = KESimStateWaitAdv2 _ => None
with st = KESimStateFinal _ => None.
lemma enc_dec_ke_sim_state_wait_adv1 (x : addr * exp) :
dec_ke_sim_state_wait_adv1 (KESimStateWaitAdv1 x) = Some x.
proof. done. qed.
op is_ke_sim_state_wait_adv1 (st : ke_sim_state) : bool =
dec_ke_sim_state_wait_adv1 st <> None.
lemma is_ke_sim_state_wait_adv1 (x : addr * exp) :
is_ke_sim_state_wait_adv1 (KESimStateWaitAdv1 x).
proof. done. qed.
op dec_ke_sim_state_wait_req2 (st : ke_sim_state) :
(addr * exp * exp) option =
with st = KESimStateWaitReq1 => None
with st = KESimStateWaitAdv1 _ => None
with st = KESimStateWaitReq2 x => Some x
with st = KESimStateWaitAdv2 _ => None
with st = KESimStateFinal _ => None.
lemma enc_dec_ke_sim_state_wait_req2 (x : addr * exp * exp) :
dec_ke_sim_state_wait_req2 (KESimStateWaitReq2 x) = Some x.
proof. done. qed.
op is_ke_sim_state_wait_req2 (st : ke_sim_state) : bool =
dec_ke_sim_state_wait_req2 st <> None.
lemma is_ke_sim_state_wait_req2 (x : addr * exp * exp) :
is_ke_sim_state_wait_req2 (KESimStateWaitReq2 x).
proof. done. qed.
op dec_ke_sim_state_wait_adv2 (st : ke_sim_state) :
(addr * exp * exp) option =
with st = KESimStateWaitReq1 => None
with st = KESimStateWaitAdv1 _ => None
with st = KESimStateWaitReq2 _ => None
with st = KESimStateWaitAdv2 x => Some x
with st = KESimStateFinal _ => None.
lemma enc_dec_ke_sim_state_wait_adv2 (x : addr * exp * exp) :
dec_ke_sim_state_wait_adv2 (KESimStateWaitAdv2 x) = Some x.
proof. done. qed.
op is_ke_sim_state_wait_adv2 (st : ke_sim_state) : bool =
dec_ke_sim_state_wait_adv2 st <> None.
lemma is_ke_sim_state_wait_adv2 (x : addr * exp * exp) :
is_ke_sim_state_wait_adv2 (KESimStateWaitAdv2 x).
proof. done. qed.
op dec_ke_sim_state_final (st : ke_sim_state) :
(addr * exp * exp) option =
with st = KESimStateWaitReq1 => None
with st = KESimStateWaitAdv1 _ => None
with st = KESimStateWaitReq2 _ => None
with st = KESimStateWaitAdv2 _ => None
with st = KESimStateFinal x => Some x.
lemma enc_dec_ke_sim_state_final (x : addr * exp * exp) :
dec_ke_sim_state_final (KESimStateFinal x) = Some x.
proof. done. qed.
op is_ke_sim_state_final (st : ke_sim_state) : bool =
dec_ke_sim_state_final st <> None.
lemma is_ke_sim_state_final (x : addr * exp * exp) :
is_ke_sim_state_final (KESimStateFinal x).
proof. done. qed.
module KESim (Adv : FUNC) = {
var self, adv : addr
var st : ke_sim_state
proc init(self_ adv_ : addr) : unit = {
self <- self_; adv <- adv_;
Adv.init(self, adv);
st <- KESimStateWaitReq1;
}
proc loop(m : msg) : msg option = {
var mod : mode; var pt1, pt2, pt1', pt2' : port; var u : univ;
var addr, addr1, addr2 : addr; var n1: int;
var q1, q2 : exp;
var r : msg option <- None;
var not_done : bool <- true;
while (not_done) {
(* m.`1 = Adv /\ m.`2.`1 = self *)
if (m.`2.`2 = ke_sim_adv_pi) { (* simulator *)
r <- None;
if (st = KESimStateWaitReq1) {
if (is_ke_sim_req1 m) {
(addr1, addr2, pt1', pt2') <- oget (dec_ke_sim_req1 m);
q1 <$ dexp;
r <-
Some
(Fwd1.fw_obs (addr1 ++ [1]) self (addr1, 3) (addr1, 4)
(univ_triple (UnivPort pt1') (UnivPort pt2')
(UnivBase (BaseKey (g ^ q1)))));
st <- KESimStateWaitAdv1 (addr1, q1);
}
}
elif (is_ke_sim_state_wait_req2 st) {
(addr, q1, q2) <- oget (dec_ke_sim_state_wait_req2 st);
if (is_ke_sim_req2 m) {
(addr1, addr2) <- oget (dec_ke_sim_req2 m);
r <-
Some (Fwd2.fw_obs (addr ++ [2]) self (addr, 4) (addr, 3)
(UnivBase (BaseKey (g ^ q2))));
st <- KESimStateWaitAdv2 (addr, q1, q2);
}