diff --git a/.gitignore b/.gitignore
index 0dbc3ac4..19817e05 100644
--- a/.gitignore
+++ b/.gitignore
@@ -4,4 +4,5 @@
 /po/messages.pot
 /galactic-armada/src/generated
 /galactic-armada/dist/
-/galactic-armada/obj/
\ No newline at end of file
+/galactic-armada/obj/
+.idea
\ No newline at end of file
diff --git a/src/SUMMARY.md b/src/SUMMARY.md
index 80d15ab1..9d4aaeef 100644
--- a/src/SUMMARY.md
+++ b/src/SUMMARY.md
@@ -29,6 +29,7 @@
 - [Input](part2/input.md)
 - [Collision](part2/collision.md)
 - [Bricks](part2/bricks.md)
+- [Decimal Numbers](part2/bcd.md)
 - [Work in progress](part2/wip.md)
 
 # Part III — Our second game
diff --git a/src/assets/part2/img/bcd-tilemap.png b/src/assets/part2/img/bcd-tilemap.png
new file mode 100644
index 00000000..abc32824
Binary files /dev/null and b/src/assets/part2/img/bcd-tilemap.png differ
diff --git a/src/assets/part2/img/bcd-tileset.png b/src/assets/part2/img/bcd-tileset.png
new file mode 100644
index 00000000..ba0b6fcf
Binary files /dev/null and b/src/assets/part2/img/bcd-tileset.png differ
diff --git a/src/part2/bcd.md b/src/part2/bcd.md
new file mode 100644
index 00000000..9c0cdfd2
--- /dev/null
+++ b/src/part2/bcd.md
@@ -0,0 +1,106 @@
+# Decimal Numbers
+
+Now that we can make the bricks disappear on impact, we should probably get some reward, like points!
+We'll start off with a score of 0 and then increase the score by 1 point each time a brick gets destroyed.
+Then we can display the score on a scoreboard.
+
+## BCD
+
+As we're stingy when it comes to memory use, we will only use one byte. There are different ways of saving and retrieving numbers as decimals, but this time we will choose something called "Packed Binary Coded Decimal" or packed BCD for short.
+
+BCD is a way of storing decimal numbers in bytes, not using A-F, so $A would be 10 which consists of the digits 1 and 0.
+
+Remember how bits, nibbles and bytes work? Go and have a look at the [Hexadeciamal](../part1/bin_and_hex.md) section if you need a reminder.
+
+The "packed" part means that we pack 2 digits into one byte. A byte contains 8 bits and inside 4 bits we can already store numbers between `$0` (`%0000`) and `$F` (`%1111`), which is more than sufficent to store a number between 0 and 9.
+
+For example the number 35 (my favorite Pokémon) contains the number 3 `%0011` and 5 `%0101` and as a packed BCD this is `%00110101`
+
+## Calculating the score
+
+Now let's start by defining a global variable (memory location) for the score:
+
+```rgbasm,linenos,start={{#line_no_of "" ../../unbricked/bcd/main.asm:score-variable}}
+{{#include ../../unbricked/bcd/main.asm:score-variable}}
+```
+
+And we'll set this to zero when initializing the other global variables.
+
+```rgbasm,linenos,start={{#line_no_of "" ../../unbricked/bcd/main.asm:init-variables}}
+{{#include ../../unbricked/bcd/main.asm:init-variables}}
+```
+
+Now we'll write a function to increase the score, right behind the `IsWallTile` function.
+Don't worry about the call to `UpdateScoreBoard`, we'll get into that in a bit.
+
+```rgbasm,linenos,start={{#line_no_of "" ../../unbricked/bcd/main.asm:increase-score}}
+{{#include ../../unbricked/bcd/main.asm:increase-score}}
+```
+
+Let's have a look at what's going on there:
+We set A to 1 and clear the carry flag
+We add the score variable (contents of memory location `wScore`) to a, so now A has our increased score.
+
+So far so good, but what if the score was 9 and we add 1? The processor thinks in binary only and will do the following math:
+
+`%00001001` + `%00000001` = `%00001010` = `$A`
+
+That's a hexadecimal representation of 10, and we need to adjust it to become decimal. `DAA` or "Decimal Adjust after Addition," does just that.
+After executing `DAA` our accumulator will be adjusted from `%00001010` to `%00010000`; a 1 in the left nibble and a 0 in the right one. A more detailed article about `DAA` on the Game Boy can be found [here](https://blog.ollien.com/posts/gb-daa/).
+
+Then we store the score back into `wScore` and finally, we call a function that will update the score board, which we will implement next.
+
+Of course, we still need to call it on impact. To do this, we add a call to `IncreaseScorePackedBCD` after each collision handler (we had a left and a right collision) in `CheckAndHandleBrick`
+
+```rgbasm,linenos,start={{#line_no_of "" ../../unbricked/bcd/main.asm:check-for-brick}}
+{{#include ../../unbricked/bcd/main.asm:check-for-brick}}
+```
+
+## Digit tiles
+
+Before we can display the score we'll need to add some graphics for the numbers 0-9. We already have some ready-made digits for this project, so you can copy [this premade file](https://github.com/gbdev/gb-asm-tutorial/raw/master/unbricked/bcd/digit-tileset.asm), and paste it at the end of your tile set, just before the `TilesEnd` label. Your tile set will look like this:
+
+![Screenshot of tile set with digits added at the end](../assets/part2/img/bcd-tileset.png)
+
+So we can easily remember where the digits start, let's add a constant called `DIGIT_OFFSET` to point us to where the digits are relative to the start of the tile set: `$1A`
+
+```rgbasm,linenos,start={{#line_no_of "" ../../unbricked/bcd/main.asm:digit-offset}}
+{{#include ../../unbricked/bcd/main.asm:digit-offset}}
+```
+
+Let's make an assumption, that we cannot get a score higher than 99 ([what could possibly go wrong](https://en.wikipedia.org/wiki/Year_2000_problem)) so two digits are enough.
+
+We can start with showing two zeroes (the tile at offset `$1A`) on our initial map. Let's put them on row 3, starting 4 tiles to the left.
+You can copy-paste the tile set from [this file](https://github.com/gbdev/gb-asm-tutorial/raw/master/unbricked/bcd/tilemap.asm)
+
+This should make the tile set look like this on start up:
+
+![Screenshot of tile map with two zeroes added](../assets/part2/img/bcd-tilemap.png)
+
+> **Tip:** You can find the address in VRAM in your emulator's tile map viewer by selecting the tile and looking at the index.
+> The screenshot above is from emulucious.
+
+Let's remember their positions by defining a constant for VRAM location of the 10s and the 1s at the top of our file, behind the other constants.
+
+```rgbasm,linenos,start={{#line_no_of "" ../../unbricked/bcd/main.asm:score-tile-location}}
+{{#include ../../unbricked/bcd/main.asm:score-tile-location}}
+```
+## Displaying the score
+
+Now we need to write the missing `UpdateScoreBoard` function that will update the score board:
+
+```rgbasm,linenos,start={{#line_no_of "" ../../unbricked/bcd/main.asm:update-score-board}}
+{{#include ../../unbricked/bcd/main.asm:update-score-board}}
+```
+
+First we load the score (stored in the wScore memory location) into register A. Recall that the score is stored in packed BCD format, where the upper nibble contains the tens digit and the lower nibble contains the ones digit.
+
+The `and %11110000` operation masks the lower nibble (the ones digit) so that only the upper nibble (the tens digit) remains in `A`.
+
+The `rrca` instructions perform a rotate right operation on `A` four times. This effectively shifts the tens digit to the lower nibble, making it ready to map to a digit tile.
+
+We then add the `DIGIT_OFFSET` constant to the tens digit to calculate the tile address for the digit. This address is stored in the `SCORE_TENS` VRAM location, which updates the display to show the tens digit.
+
+Finally, we repeat the process for the ones digit: We mask the tens digit from `A` using `and %00001111`, no need to rotate this time.
+
+Now we can display the score on the screen! We'll need to call `UpdateScoreBoard` after each time the score is updated. We've already done this in the `IncreaseScorePackedBCD` function, so we're all set!
\ No newline at end of file
diff --git a/unbricked/bcd/digit-tileset.asm b/unbricked/bcd/digit-tileset.asm
new file mode 100644
index 00000000..fbc51ae2
--- /dev/null
+++ b/unbricked/bcd/digit-tileset.asm
@@ -0,0 +1,91 @@
+    ; digits
+    ; 0
+    dw `33333333
+    dw `33000033
+    dw `30033003
+    dw `30033003
+    dw `30033003
+    dw `30033003
+    dw `33000033
+    dw `33333333
+    ; 1
+    dw `33333333
+    dw `33300333
+    dw `33000333
+    dw `33300333
+    dw `33300333
+    dw `33300333
+    dw `33000033
+    dw `33333333
+    ; 2
+    dw `33333333
+    dw `33000033
+    dw `30330003
+    dw `33330003
+    dw `33000333
+    dw `30003333
+    dw `30000003
+    dw `33333333
+    ; 3
+    dw `33333333
+    dw `30000033
+    dw `33330003
+    dw `33000033
+    dw `33330003
+    dw `33330003
+    dw `30000033
+    dw `33333333
+    ; 4
+    dw `33333333
+    dw `33000033
+    dw `30030033
+    dw `30330033
+    dw `30330033
+    dw `30000003
+    dw `33330033
+    dw `33333333
+    ; 5
+    dw `33333333
+    dw `30000033
+    dw `30033333
+    dw `30000033
+    dw `33330003
+    dw `30330003
+    dw `33000033
+    dw `33333333
+    ; 6
+    dw `33333333
+    dw `33000033
+    dw `30033333
+    dw `30000033
+    dw `30033003
+    dw `30033003
+    dw `33000033
+    dw `33333333
+    ; 7
+    dw `33333333
+    dw `30000003
+    dw `33333003
+    dw `33330033
+    dw `33300333
+    dw `33000333
+    dw `33000333
+    dw `33333333
+    ; 8
+    dw `33333333
+    dw `33000033
+    dw `30333003
+    dw `33000033
+    dw `30333003
+    dw `30333003
+    dw `33000033
+    dw `33333333
+    ; 9
+    dw `33333333
+    dw `33000033
+    dw `30330003
+    dw `30330003
+    dw `33000003
+    dw `33330003
+    dw `33000033
+    dw `33333333
\ No newline at end of file
diff --git a/unbricked/bcd/main.asm b/unbricked/bcd/main.asm
new file mode 100644
index 00000000..ba623a32
--- /dev/null
+++ b/unbricked/bcd/main.asm
@@ -0,0 +1,760 @@
+INCLUDE "hardware.inc"
+; ANCHOR: digit-offset
+DEF BRICK_LEFT EQU $05
+DEF BRICK_RIGHT EQU $06
+DEF BLANK_TILE EQU $08
+DEF DIGIT_OFFSET EQU $1A
+; ANCHOR_END: digit-offset
+; ANCHOR: score-tile-location
+DEF SCORE_TENS   EQU $9870
+DEF SCORE_ONES   EQU $9871
+; ANCHOR_END: score-tile-location
+
+SECTION "Header", ROM0[$100]
+
+	jp EntryPoint
+
+	ds $150 - @, 0 ; Make room for the header
+
+EntryPoint:
+	; Do not turn the LCD off outside of VBlank
+WaitVBlank:
+	ld a, [rLY]
+	cp 144
+	jp c, WaitVBlank
+
+	; Turn the LCD off
+	ld a, 0
+	ld [rLCDC], a
+
+	; Copy the tile data
+	ld de, Tiles
+	ld hl, $9000
+	ld bc, TilesEnd - Tiles
+	call Memcopy
+
+	; Copy the tilemap
+	ld de, Tilemap
+	ld hl, $9800
+	ld bc, TilemapEnd - Tilemap
+	call Memcopy
+
+	; Copy the paddle tile
+	ld de, Paddle
+	ld hl, $8000
+	ld bc, PaddleEnd - Paddle
+	call Memcopy
+
+	; Copy the ball tile
+	ld de, Ball
+	ld hl, $8010
+	ld bc, BallEnd - Ball
+	call Memcopy
+
+	xor a, a
+	ld b, 160
+	ld hl, _OAMRAM
+ClearOam:
+	ld [hli], a
+	dec b
+	jp nz, ClearOam
+
+	; Initialize the paddle sprite in OAM
+	ld hl, _OAMRAM
+	ld a, 128 + 16
+	ld [hli], a
+	ld a, 16 + 8
+	ld [hli], a
+	ld a, 0
+	ld [hli], a
+	ld [hli], a
+	; Now initialize the ball sprite
+	ld a, 100 + 16
+	ld [hli], a
+	ld a, 32 + 8
+	ld [hli], a
+	ld a, 1
+	ld [hli], a
+	ld a, 0
+	ld [hli], a
+
+	; The ball starts out going up and to the right
+	ld a, 1
+	ld [wBallMomentumX], a
+	ld a, -1
+	ld [wBallMomentumY], a
+
+	; Turn the LCD on
+	ld a, LCDCF_ON | LCDCF_BGON | LCDCF_OBJON
+	ld [rLCDC], a
+
+	; During the first (blank) frame, initialize display registers
+	ld a, %11100100
+	ld [rBGP], a
+	ld a, %11100100
+	ld [rOBP0], a
+    ; ANCHOR: init-variables
+	; Initialize global variables
+	ld a, 0
+	ld [wFrameCounter], a
+	ld [wCurKeys], a
+	ld [wNewKeys], a
+	ld [wScore], a
+	; ANCHOR_END: init-variables
+
+Main:
+	ld a, [rLY]
+	cp 144
+	jp nc, Main
+WaitVBlank2:
+	ld a, [rLY]
+	cp 144
+	jp c, WaitVBlank2
+
+	; Add the ball's momentum to its position in OAM.
+	ld a, [wBallMomentumX]
+	ld b, a
+	ld a, [_OAMRAM + 5]
+	add a, b
+	ld [_OAMRAM + 5], a
+
+	ld a, [wBallMomentumY]
+	ld b, a
+	ld a, [_OAMRAM + 4]
+	add a, b
+	ld [_OAMRAM + 4], a
+
+BounceOnTop:
+	; Remember to offset the OAM position!
+	; (8, 16) in OAM coordinates is (0, 0) on the screen.
+	ld a, [_OAMRAM + 4]
+	sub a, 16 + 1
+	ld c, a
+	ld a, [_OAMRAM + 5]
+	sub a, 8
+	ld b, a
+	call GetTileByPixel ; Returns tile address in hl
+	ld a, [hl]
+	call IsWallTile
+	jp nz, BounceOnRight
+	call CheckAndHandleBrick
+	ld a, 1
+	ld [wBallMomentumY], a
+
+BounceOnRight:
+	ld a, [_OAMRAM + 4]
+	sub a, 16
+	ld c, a
+	ld a, [_OAMRAM + 5]
+	sub a, 8 - 1
+	ld b, a
+	call GetTileByPixel
+	ld a, [hl]
+	call IsWallTile
+	jp nz, BounceOnLeft
+	call CheckAndHandleBrick
+	ld a, -1
+	ld [wBallMomentumX], a
+
+BounceOnLeft:
+	ld a, [_OAMRAM + 4]
+	sub a, 16
+	ld c, a
+	ld a, [_OAMRAM + 5]
+	sub a, 8 + 1
+	ld b, a
+	call GetTileByPixel
+	ld a, [hl]
+	call IsWallTile
+	jp nz, BounceOnBottom
+	call CheckAndHandleBrick
+	ld a, 1
+	ld [wBallMomentumX], a
+
+BounceOnBottom:
+	ld a, [_OAMRAM + 4]
+	sub a, 16 - 1
+	ld c, a
+	ld a, [_OAMRAM + 5]
+	sub a, 8
+	ld b, a
+	call GetTileByPixel
+	ld a, [hl]
+	call IsWallTile
+	jp nz, BounceDone
+	call CheckAndHandleBrick
+	ld a, -1
+	ld [wBallMomentumY], a
+BounceDone:
+
+	; First, check if the ball is low enough to bounce off the paddle.
+	ld a, [_OAMRAM]
+	ld b, a
+	ld a, [_OAMRAM + 4]
+	cp a, b
+	jp nz, PaddleBounceDone
+	; Now let's compare the X positions of the objects to see if they're touching.
+	ld a, [_OAMRAM + 1]
+	ld b, a
+	ld a, [_OAMRAM + 5]
+	add a, 16
+	cp a, b
+	jp c, PaddleBounceDone
+	sub a, 16 + 8
+	cp a, b
+	jp nc, PaddleBounceDone
+
+	ld a, -1
+	ld [wBallMomentumY], a
+
+PaddleBounceDone:
+
+	; Check the current keys every frame and move left or right.
+	call Input
+
+	; First, check if the left button is pressed.
+CheckLeft:
+	ld a, [wCurKeys]
+	and a, PADF_LEFT
+	jp z, CheckRight
+Left:
+	; Move the paddle one pixel to the left.
+	ld a, [_OAMRAM + 1]
+	dec a
+	; If we've already hit the edge of the playfield, don't move.
+	cp a, 15
+	jp z, Main
+	ld [_OAMRAM + 1], a
+	jp Main
+
+; Then check the right button.
+CheckRight:
+	ld a, [wCurKeys]
+	and a, PADF_RIGHT
+	jp z, Main
+Right:
+	; Move the paddle one pixel to the right.
+	ld a, [_OAMRAM + 1]
+	inc a
+	; If we've already hit the edge of the playfield, don't move.
+	cp a, 105
+	jp z, Main
+	ld [_OAMRAM + 1], a
+	jp Main
+
+; Convert a pixel position to a tilemap address
+; hl = $9800 + X + Y * 32
+; @param b: X
+; @param c: Y
+; @return hl: tile address
+GetTileByPixel:
+	; First, we need to divide by 8 to convert a pixel position to a tile position.
+	; After this we want to multiply the Y position by 32.
+	; These operations effectively cancel out so we only need to mask the Y value.
+	ld a, c
+	and a, %11111000
+	ld l, a
+	ld h, 0
+	; Now we have the position * 8 in hl
+	add hl, hl ; position * 16
+	add hl, hl ; position * 32
+	; Just add the X position and offset to the tilemap, and we're done.
+	ld a, b
+	srl a ; a / 2
+	srl a ; a / 4
+	srl a ; a / 8
+	add a, l
+	ld l, a
+	adc a, h
+	sub a, l
+	ld h, a
+	ld bc, $9800
+	add hl, bc
+	ret
+
+; @param a: tile ID
+; @return z: set if a is a wall.
+IsWallTile:
+	cp a, $00
+	ret z
+	cp a, $01
+	ret z
+	cp a, $02
+	ret z
+	cp a, $04
+	ret z
+	cp a, $05
+	ret z
+	cp a, $06
+	ret z
+	cp a, $07
+	ret
+
+; ANCHOR: increase-score
+; Increase score by 1 and store it as a 1 byte packed BCD number
+; changes A and HL
+IncreaseScorePackedBCD:
+    xor a               ; clear carry flag and a
+    inc a               ; a = 1
+    ld hl, wScore       ; load score
+    adc [hl]            ; add 1
+    daa                 ; convert to BCD
+    ld [hl], a          ; store score
+    call UpdateScoreBoard
+    ret
+; ANCHOR_END: increase-score
+
+; ANCHOR: update-score-board
+; Read the packed BCD score from wScore and updates the score display
+UpdateScoreBoard:
+    ld a, [wScore]      ; Get the Packed score
+    and %11110000       ; Mask the lower nibble
+    rrca                ; Move the upper nibble to the lower nibble (divide by 16)
+    rrca
+    rrca
+    rrca
+    add a, DIGIT_OFFSET ; Offset + add to get the digit tile
+    ld [SCORE_TENS], a  ; Show the digit on screen
+
+    ld a, [wScore]      ; Get the packed score again
+    and %00001111       ; Mask the upper nibble
+    add a, DIGIT_OFFSET ; Offset + add to get the digit tile again
+    ld [SCORE_ONES], a  ; Show the digit on screen
+    ret
+; ANCHOR_END: update-score-board
+
+; ANCHOR: check-for-brick
+; Checks if a brick was collided with and breaks it if possible.
+; @param hl: address of tile.
+CheckAndHandleBrick:
+	ld a, [hl]
+	cp a, BRICK_LEFT
+	jr nz, CheckAndHandleBrickRight
+	; Break a brick from the left side.
+	ld [hl], BLANK_TILE
+	inc hl
+	ld [hl], BLANK_TILE
+	call IncreaseScorePackedBCD
+CheckAndHandleBrickRight:
+	cp a, BRICK_RIGHT
+	ret nz
+	; Break a brick from the right side.
+	ld [hl], BLANK_TILE
+	dec hl
+	ld [hl], BLANK_TILE
+	call IncreaseScorePackedBCD
+	ret
+; ANCHOR_END: check-for-brick
+
+Input:
+  ; Poll half the controller
+  ld a, P1F_GET_BTN
+  call .onenibble
+  ld b, a ; B7-4 = 1; B3-0 = unpressed buttons
+
+  ; Poll the other half
+  ld a, P1F_GET_DPAD
+  call .onenibble
+  swap a ; A3-0 = unpressed directions; A7-4 = 1
+  xor a, b ; A = pressed buttons + directions
+  ld b, a ; B = pressed buttons + directions
+
+  ; And release the controller
+  ld a, P1F_GET_NONE
+  ldh [rP1], a
+
+  ; Combine with previous wCurKeys to make wNewKeys
+  ld a, [wCurKeys]
+  xor a, b ; A = keys that changed state
+  and a, b ; A = keys that changed to pressed
+  ld [wNewKeys], a
+  ld a, b
+  ld [wCurKeys], a
+  ret
+
+.onenibble
+  ldh [rP1], a ; switch the key matrix
+  call .knownret ; burn 10 cycles calling a known ret
+  ldh a, [rP1] ; ignore value while waiting for the key matrix to settle
+  ldh a, [rP1]
+  ldh a, [rP1] ; this read counts
+  or a, $F0 ; A7-4 = 1; A3-0 = unpressed keys
+.knownret
+  ret
+
+; Copy bytes from one area to another.
+; @param de: Source
+; @param hl: Destination
+; @param bc: Length
+Memcopy:
+	ld a, [de]
+	ld [hli], a
+	inc de
+	dec bc
+	ld a, b
+	or a, c
+	jp nz, Memcopy
+	ret
+
+Tiles:
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33322222
+	dw `33322222
+	dw `33322222
+	dw `33322211
+	dw `33322211
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `22222222
+	dw `22222222
+	dw `22222222
+	dw `11111111
+	dw `11111111
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `22222333
+	dw `22222333
+	dw `22222333
+	dw `11222333
+	dw `11222333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33322211
+	dw `33322211
+	dw `33322211
+	dw `33322211
+	dw `33322211
+	dw `33322211
+	dw `33322211
+	dw `33322211
+	dw `22222222
+	dw `20000000
+	dw `20111111
+	dw `20111111
+	dw `20111111
+	dw `20111111
+	dw `22222222
+	dw `33333333
+	dw `22222223
+	dw `00000023
+	dw `11111123
+	dw `11111123
+	dw `11111123
+	dw `11111123
+	dw `22222223
+	dw `33333333
+	dw `11222333
+	dw `11222333
+	dw `11222333
+	dw `11222333
+	dw `11222333
+	dw `11222333
+	dw `11222333
+	dw `11222333
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `11001100
+	dw `11111111
+	dw `11111111
+	dw `21212121
+	dw `22222222
+	dw `22322232
+	dw `23232323
+	dw `33333333
+	; My custom logo (tail)
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33302333
+	dw `33333133
+	dw `33300313
+	dw `33300303
+	dw `33013330
+	dw `30333333
+	dw `03333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `03333333
+	dw `30333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333330
+	dw `33333320
+	dw `33333013
+	dw `33330333
+	dw `33100333
+	dw `31001333
+	dw `20001333
+	dw `00000333
+	dw `00000033
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33330333
+	dw `33300333
+	dw `33333333
+	dw `33033333
+	dw `33133333
+	dw `33303333
+	dw `33303333
+	dw `33303333
+	dw `33332333
+	dw `33332333
+	dw `33333330
+	dw `33333300
+	dw `33333300
+	dw `33333100
+	dw `33333000
+	dw `33333000
+	dw `33333100
+	dw `33333300
+	dw `00000001
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `10000333
+	dw `00000033
+	dw `00000003
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `33332333
+	dw `33302333
+	dw `32003333
+	dw `00003333
+	dw `00003333
+	dw `00013333
+	dw `00033333
+	dw `00033333
+	dw `33333300
+	dw `33333310
+	dw `33333330
+	dw `33333332
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `30000000
+	dw `33000000
+	dw `33333000
+	dw `33333333
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000003
+	dw `00000033
+	dw `00003333
+	dw `02333333
+	dw `33333333
+	dw `00333333
+	dw `03333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+	dw `33333333
+
+	; digits
+        ; 0
+        dw `33333333
+        dw `33000033
+        dw `30033003
+        dw `30033003
+        dw `30033003
+        dw `30033003
+        dw `33000033
+        dw `33333333
+        ; 1
+        dw `33333333
+        dw `33300333
+        dw `33000333
+        dw `33300333
+        dw `33300333
+        dw `33300333
+        dw `33000033
+        dw `33333333
+        ; 2
+        dw `33333333
+        dw `33000033
+        dw `30330003
+        dw `33330003
+        dw `33000333
+        dw `30003333
+        dw `30000003
+        dw `33333333
+        ; 3
+        dw `33333333
+        dw `30000033
+        dw `33330003
+        dw `33000033
+        dw `33330003
+        dw `33330003
+        dw `30000033
+        dw `33333333
+        ; 4
+        dw `33333333
+        dw `33000033
+        dw `30030033
+        dw `30330033
+        dw `30330033
+        dw `30000003
+        dw `33330033
+        dw `33333333
+        ; 5
+        dw `33333333
+        dw `30000033
+        dw `30033333
+        dw `30000033
+        dw `33330003
+        dw `30330003
+        dw `33000033
+        dw `33333333
+        ; 6
+        dw `33333333
+        dw `33000033
+        dw `30033333
+        dw `30000033
+        dw `30033003
+        dw `30033003
+        dw `33000033
+        dw `33333333
+        ; 7
+        dw `33333333
+        dw `30000003
+        dw `33333003
+        dw `33330033
+        dw `33300333
+        dw `33000333
+        dw `33000333
+        dw `33333333
+        ; 8
+        dw `33333333
+        dw `33000033
+        dw `30333003
+        dw `33000033
+        dw `30333003
+        dw `30333003
+        dw `33000033
+        dw `33333333
+        ; 9
+        dw `33333333
+        dw `33000033
+        dw `30330003
+        dw `30330003
+        dw `33000003
+        dw `33330003
+        dw `33000033
+        dw `33333333
+TilesEnd:
+
+Tilemap:
+    db $00, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01, $02, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $07, $03, $03, $1A, $1A, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $0A, $0B, $0C, $0D, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $0E, $0F, $10, $11, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $12, $13, $14, $15, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $16, $17, $18, $19, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $09, $09, $09, $09, $09, $09, $09, $09, $09, $09, $09, $09, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+TilemapEnd:
+
+Paddle:
+	dw `33333333
+	dw `32222223
+	dw `33333333
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+	dw `00000000
+PaddleEnd:
+
+Ball:
+	dw `00330000
+	dw `03223000
+	dw `32222300
+	dw `32222300
+	dw `03223000
+	dw `00330000
+	dw `00000000
+	dw `00000000
+BallEnd:
+
+SECTION "Counter", WRAM0
+wFrameCounter: db
+
+SECTION "Input Variables", WRAM0
+wCurKeys: db
+wNewKeys: db
+
+SECTION "Ball Data", WRAM0
+wBallMomentumX: db
+wBallMomentumY: db
+
+; ANCHOR: score-variable
+SECTION "Score", WRAM0
+wScore: db
+; ANCHOR_END: score-variable
\ No newline at end of file
diff --git a/unbricked/bcd/tilemap.asm b/unbricked/bcd/tilemap.asm
new file mode 100644
index 00000000..5214cdba
--- /dev/null
+++ b/unbricked/bcd/tilemap.asm
@@ -0,0 +1,20 @@
+Tilemap:
+    db $00, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01, $01, $02, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $07, $03, $03, $1A, $1A, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $05, $06, $05, $06, $05, $06, $05, $06, $05, $06, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $0A, $0B, $0C, $0D, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $0E, $0F, $10, $11, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $12, $13, $14, $15, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $08, $07, $03, $16, $17, $18, $19, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+    db $04, $09, $09, $09, $09, $09, $09, $09, $09, $09, $09, $09, $09, $07, $03, $03, $03, $03, $03, $03, 0,0,0,0,0,0,0,0,0,0,0,0
+TilemapEnd:
\ No newline at end of file