From 04e727a714b5464b5e4a63a605bea5b6d6b42997 Mon Sep 17 00:00:00 2001
From: Horea Christian <chr@chymera.eu>
Date: Thu, 14 Dec 2023 14:17:41 -0500
Subject: [PATCH] dev-python/neo: add 0.12.0

Signed-off-by: Horea Christian <chr@chymera.eu>
---
 dev-python/neo/Manifest          |  1 +
 dev-python/neo/neo-0.12.0.ebuild | 57 ++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 dev-python/neo/neo-0.12.0.ebuild

diff --git a/dev-python/neo/Manifest b/dev-python/neo/Manifest
index e3b133b9ec3..346e022b850 100644
--- a/dev-python/neo/Manifest
+++ b/dev-python/neo/Manifest
@@ -1,2 +1,3 @@
 DIST neo-0.11.0.tar.gz 9411608 BLAKE2B 9257fd8ff9eea8ec80b0a4eb701b63a9db10d51e6f145b704eb5e9a394dd13a5c6e567cb3469fa4d86f538637f80e9c660823d358bb7ddfd651291dc5df73450 SHA512 dab4832317c8dc6a794ffc9fb118124734fa2428c0527eb9c86bc3d35195a34bdb162bc0a44a3604cb8067fff7263ab5b106c0f9871007a093e7185df5ba9993
 DIST neo-0.11.1.tar.gz 3906151 BLAKE2B 26b60c715d6f3ec017cdb909c1f54b1509db4862f0630ab6d60b4b07153d5cb8512fbf16dd9039d1998b08e0f9e828bb271d4f482cc2d34a5d17a010ef4d203b SHA512 1f93a9eea020ee40f792f038bef76e053ff4f6e05951f78afa70bf4009bac3da8222be57c2cee88ae5e7539c5c8978cf50bf52cce787dbacafe6d5450d5e1aa7
+DIST neo-0.12.0.tar.gz 28377158 BLAKE2B efc6ae96d8cf8325355367af482d4e6dcc0dc3e3c5f3d449076a1c3ef32f530f777a2b125c946360b05a070cd75ae3f04b31a9e63d9bee7fecf437c3a19fc284 SHA512 1849c5074afb71cba7e90a78fa51b9967b27cb3f0b6242cfbadc3c29faf7a4a13da0a15a1c43cf43df810a5c0ed0b45cf60b42f3ed83520689acc27d3bde07b9
diff --git a/dev-python/neo/neo-0.12.0.ebuild b/dev-python/neo/neo-0.12.0.ebuild
new file mode 100644
index 00000000000..6e058728ed4
--- /dev/null
+++ b/dev-python/neo/neo-0.12.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="Read and represent a wide range of neurophysiology file formats in Python"
+HOMEPAGE="https://github.com/NeuralEnsemble/python-neo"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/quantities[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/h5py[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/probeinterface[${PYTHON_USEDEP}]
+		dev-python/pynwb[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+		dev-vcs/datalad[${PYTHON_USEDEP}]
+	)
+"
+# Testing deps also need:
+# igor
+# pyedflib https://github.com/holgern/pyedflib
+# klusta
+# nixio
+# sonpy
+# ipython
+
+distutils_enable_tests pytest
+
+python_test() {
+	# Reported upstream
+	# https://github.com/NeuralEnsemble/python-neo/issues/1037
+	local EPYTEST_IGNORE=(
+		neo/test/iotest/*
+		neo/test/rawiotest/*
+	)
+	# Requires dynamic data download
+	local EPYTEST_DESELECT=(
+		neo/test/utils/test_datasets.py::TestDownloadDataset::test_download_dataset
+	)
+	epytest
+}