build.gradle

buildscript {
	ext {
		springBootVersion = '2.0.1.RELEASE'
	}
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
		classpath('se.transmode.gradle:gradle-docker:1.2')
	}
}

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'

// This is used as the docker image prefix (org)
group = 'stelylan'
sourceCompatibility = 1.8

repositories {
	mavenCentral()
	maven { url "https://repo.spring.io/milestone" }
}

jar {
	baseName = 'spring-boot-docker'
	version =  '1.0.0'
}

ext {
	springCloudVersion = 'Finchley.RC1'
}

dependencies {
	compile('org.springframework.boot:spring-boot-starter-data-jpa')
	compile('org.springframework.boot:spring-boot-starter-web')
	compile('org.springframework.boot:spring-boot-starter-data-redis')
	compile('org.springframework.cloud:spring-cloud-starter-openfeign')
	compile('org.springframework.cloud:spring-cloud-starter-netflix-hystrix')
	compile('org.springframework.boot:spring-boot-starter-actuator')
	compile('org.springframework.kafka:spring-kafka')
	compile('com.google.protobuf:protobuf-java:2.6.1')
	compile('com.squareup.okhttp3:okhttp:3.9.0')
	compile('com.google.code.gson:gson:2.8.2')
	compile("org.springframework.boot:spring-boot-configuration-processor")
	compile 'com.alibaba:druid-spring-boot-starter:1.1.9'
	compile 'io.jsonwebtoken:jjwt:0.9.0'
	compile('org.apache.commons:commons-lang3:3.7')
	runtime('org.postgresql:postgresql')
	testCompile('org.springframework.boot:spring-boot-starter-test')
}

dependencyManagement {
	imports {
		mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
	}
}

apply plugin: 'docker'

task buildDocker(type: Docker, dependsOn: build) {
	applicationName = jar.baseName
	dockerfile = file('src/main/docker/Dockerfile')
	doFirst {
		copy {
			from jar
			into stageDir
		}
	}
}