-
Notifications
You must be signed in to change notification settings - Fork 7
/
Copy pathQssEditor.pro
459 lines (381 loc) · 19.4 KB
/
QssEditor.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
TARGET = QssEditor
TEMPLATE = app
QT += core gui
QT += sql
greaterThan(QT_MAJOR_VERSION, 4): QT *= widgets printsupport
macx: greaterThan(QT_MAJOR_VERSION, 4): QT *= macextras
NVER1=0
NVER2=6
NVER3=0
include($$_PRO_FILE_PWD_/QssEditor-common.pri)
SOURCES += main.cpp \
qsseditor.cpp \
qscilexerqss.cpp \
project.cpp \
settings.cpp \
searchandreplace.cpp \
options.cpp \
about.cpp
HEADERS += qsseditor.h \
qscilexerqss.h \
project.h \
settings.h \
searchandreplace.h \
options.h \
about.h \
tools.h
FORMS += qsseditor.ui \
searchandreplace.ui \
options.ui \
about.ui
RESOURCES += qsseditor.qrc
RC_FILE = qsseditor.rc
unix:!mac {
CONFIG += qscintilla2
}
#===============================================
# Testing widgets
WIDGETSPATH = d:/001-Work/03-Ru/03-Ru-600/55-soft/src/gui/dashboard
#include($$WIDGETSPATH/../dialogs/addedit_instrument_dialog.pri)
#include($$WIDGETSPATH/dut_panel.pri)
#include($$WIDGETSPATH/flowgenerator.pri)
#include($$WIDGETSPATH/floating_button.pri)
#include($$WIDGETSPATH/titlebar.pri)
#include($$WIDGETSPATH/etalon.pri)
#include($$WIDGETSPATH/measure_frame.pri)
#include($$WIDGETSPATH/3rdparty/TableViewBuddy/tableviewbuddy.pri)
#INCLUDEPATH *= $$WIDGETSPATH/../../ #global.h
#===============================================
QSCINTILLA_INTERNAL=$$(QSCINTILLA_INTERNAL)
equals(QSCINTILLA_INTERNAL, 1)|win32|mac {
message("Using internal QScintilla")
# QScintilla files
DEFINES += SCINTILLA_QT SCI_LEXER
INCLUDEPATH += $$_PRO_FILE_PWD_/qscintilla $$_PRO_FILE_PWD_/qscintilla/include $$_PRO_FILE_PWD_/qscintilla/lexlib $$_PRO_FILE_PWD_/qscintilla/Qt4Qt5 $$_PRO_FILE_PWD_/qscintilla/src
DEPENDPATH += $$_PRO_FILE_PWD_/qscintilla $$_PRO_FILE_PWD_/qscintilla/include $$_PRO_FILE_PWD_/qscintilla/lexlib $$_PRO_FILE_PWD_/qscintilla/Qt4Qt5 $$_PRO_FILE_PWD_/qscintilla/src
HEADERS += \
qscintilla/Qt4Qt5/Qsci/qsciglobal.h \
qscintilla/Qt4Qt5/Qsci/qsciscintilla.h \
qscintilla/Qt4Qt5/Qsci/qsciscintillabase.h \
qscintilla/Qt4Qt5/Qsci/qsciabstractapis.h \
qscintilla/Qt4Qt5/Qsci/qsciapis.h \
qscintilla/Qt4Qt5/Qsci/qscicommand.h \
qscintilla/Qt4Qt5/Qsci/qscicommandset.h \
qscintilla/Qt4Qt5/Qsci/qscidocument.h \
qscintilla/Qt4Qt5/Qsci/qscilexer.h \
qscintilla/Qt4Qt5/Qsci/qscilexercss.h \
qscintilla/Qt4Qt5/Qsci/qscilexercustom.h \
qscintilla/Qt4Qt5/Qsci/qscimacro.h \
qscintilla/Qt4Qt5/Qsci/qsciprinter.h \
qscintilla/Qt4Qt5/Qsci/qscistyle.h \
qscintilla/Qt4Qt5/Qsci/qscistyledtext.h \
qscintilla/Qt4Qt5/ListBoxQt.h \
qscintilla/Qt4Qt5/SciClasses.h \
qscintilla/Qt4Qt5/SciNamespace.h \
qscintilla/Qt4Qt5/ScintillaQt.h \
qscintilla/include/ILexer.h \
qscintilla/include/Platform.h \
qscintilla/include/SciLexer.h \
qscintilla/include/Scintilla.h \
qscintilla/include/ScintillaWidget.h \
qscintilla/lexlib/Accessor.h \
qscintilla/lexlib/CharacterCategory.h \
qscintilla/lexlib/CharacterSet.h \
qscintilla/lexlib/LexAccessor.h \
qscintilla/lexlib/LexerBase.h \
qscintilla/lexlib/LexerModule.h \
qscintilla/lexlib/LexerNoExceptions.h \
qscintilla/lexlib/LexerSimple.h \
qscintilla/lexlib/OptionSet.h \
qscintilla/lexlib/PropSetSimple.h \
qscintilla/lexlib/StyleContext.h \
qscintilla/lexlib/SubStyles.h \
qscintilla/lexlib/WordList.h \
qscintilla/src/AutoComplete.h \
qscintilla/src/CallTip.h \
qscintilla/src/CaseConvert.h \
qscintilla/src/CaseFolder.h \
qscintilla/src/Catalogue.h \
qscintilla/src/CellBuffer.h \
qscintilla/src/CharClassify.h \
qscintilla/src/ContractionState.h \
qscintilla/src/Decoration.h \
qscintilla/src/Document.h \
qscintilla/src/Editor.h \
qscintilla/src/ExternalLexer.h \
qscintilla/src/FontQuality.h \
qscintilla/src/Indicator.h \
qscintilla/src/KeyMap.h \
qscintilla/src/LineMarker.h \
qscintilla/src/Partitioning.h \
qscintilla/src/PerLine.h \
qscintilla/src/PositionCache.h \
qscintilla/src/RESearch.h \
qscintilla/src/RunStyles.h \
qscintilla/src/ScintillaBase.h \
qscintilla/src/Selection.h \
qscintilla/src/SplitVector.h \
qscintilla/src/Style.h \
qscintilla/src/UnicodeFromUTF8.h \
qscintilla/src/UniConversion.h \
qscintilla/src/ViewStyle.h \
qscintilla/src/XPM.h
SOURCES += \
qscintilla/Qt4Qt5/qsciscintilla.cpp \
qscintilla/Qt4Qt5/qsciscintillabase.cpp \
qscintilla/Qt4Qt5/qsciabstractapis.cpp \
qscintilla/Qt4Qt5/qsciapis.cpp \
qscintilla/Qt4Qt5/qscicommand.cpp \
qscintilla/Qt4Qt5/qscicommandset.cpp \
qscintilla/Qt4Qt5/qscidocument.cpp \
qscintilla/Qt4Qt5/qscilexer.cpp \
qscintilla/Qt4Qt5/qscilexercss.cpp \
qscintilla/Qt4Qt5/qscilexercustom.cpp \
qscintilla/Qt4Qt5/qscimacro.cpp \
qscintilla/Qt4Qt5/qsciprinter.cpp \
qscintilla/Qt4Qt5/qscistyle.cpp \
qscintilla/Qt4Qt5/qscistyledtext.cpp \
qscintilla/Qt4Qt5/MacPasteboardMime.cpp \
qscintilla/Qt4Qt5/InputMethod.cpp \
qscintilla/Qt4Qt5/SciClasses.cpp \
qscintilla/Qt4Qt5/ListBoxQt.cpp \
qscintilla/Qt4Qt5/PlatQt.cpp \
qscintilla/Qt4Qt5/ScintillaQt.cpp \
qscintilla/lexers/LexCSS.cpp \
qscintilla/lexlib/Accessor.cpp \
qscintilla/lexlib/CharacterCategory.cpp \
qscintilla/lexlib/CharacterSet.cpp \
qscintilla/lexlib/LexerBase.cpp \
qscintilla/lexlib/LexerModule.cpp \
qscintilla/lexlib/LexerNoExceptions.cpp \
qscintilla/lexlib/LexerSimple.cpp \
qscintilla/lexlib/PropSetSimple.cpp \
qscintilla/lexlib/StyleContext.cpp \
qscintilla/lexlib/WordList.cpp \
qscintilla/src/AutoComplete.cpp \
qscintilla/src/CallTip.cpp \
qscintilla/src/CaseConvert.cpp \
qscintilla/src/CaseFolder.cpp \
qscintilla/src/Catalogue.cpp \
qscintilla/src/CellBuffer.cpp \
qscintilla/src/CharClassify.cpp \
qscintilla/src/ContractionState.cpp \
qscintilla/src/Decoration.cpp \
qscintilla/src/Document.cpp \
qscintilla/src/Editor.cpp \
qscintilla/src/ExternalLexer.cpp \
qscintilla/src/Indicator.cpp \
qscintilla/src/KeyMap.cpp \
qscintilla/src/LineMarker.cpp \
qscintilla/src/PerLine.cpp \
qscintilla/src/PositionCache.cpp \
qscintilla/src/RESearch.cpp \
qscintilla/src/RunStyles.cpp \
qscintilla/src/ScintillaBase.cpp \
qscintilla/src/Selection.cpp \
qscintilla/src/Style.cpp \
qscintilla/src/UniConversion.cpp \
qscintilla/src/ViewStyle.cpp \
qscintilla/src/XPM.cpp
}
OTHER_FILES += \
LICENSE.txt \
README.txt
# distribution
SVNROOT_FOR_COMMIT="svn+ssh://[email protected]/p/qsseditor/code"
SVNROOT_FOR_DOWNLOAD="http://sourceforge.net/p/qsseditor/code/HEAD/tree/trunk"
HTTPROOT="http://sourceforge.net/p/qsseditor"
DOWNLOADROOT="http://sourceforge.net/projects/qsseditor"
DEFINES += SVNROOT_FOR_DOWNLOAD=$$sprintf("\"\\\"%1\\\"\"", $$SVNROOT_FOR_DOWNLOAD)
DEFINES += HTTPROOT=$$sprintf("\"\\\"%1\\\"\"", $$HTTPROOT)
DEFINES += DOWNLOADROOT=$$sprintf("\"\\\"%1\\\"\"", $$DOWNLOADROOT)
# files to copy to the distribution
greaterThan(QT_MAJOR_VERSION, 4) {
IMAGEPLUGINS=qico.dll qjpeg.dll
QTLIBS=Qt5Core.dll Qt5Gui.dll Qt5Widgets.dll Qt5PrintSupport.dll
QTPLATFORMS=qwindows.dll
} else {
IMAGEPLUGINS=qico4.dll qjpeg4.dll
QTLIBS=QtCore4.dll QtGui4.dll
}
isEmpty(HOST64) {
MINGW_BUILD_TYPE=dw2
} else {
MINGW_BUILD_TYPE=seh
}
MINGWLIBS=libgcc_s_$${MINGW_BUILD_TYPE}-1.dll libwinpthread-1.dll libstdc++-6.dll
LICENSES=LICENSE.txt
tag.commands += $$mle(echo "$$VERSION"> "\"$${_PRO_FILE_PWD_}/QssEditor-version.tag\"")
tag.commands += $$mle(svn -m "\"$$VERSION file tag\"" commit "\"$${_PRO_FILE_PWD_}/QssEditor-version.tag\"")
tag.commands += $$mle(svn -m "\"$$VERSION tag\"" copy "\"$$SVNROOT_FOR_COMMIT/trunk\"" "\"$$SVNROOT_FOR_COMMIT/tags/$$VERSION\"")
QMAKE_EXTRA_TARGETS += tag
!isEmpty(ZIP) {
message("7Z is found, will create custom dist targets")
# source archive
T="$${OUT_PWD}/qsseditor-$$VERSION"
distsrc.commands += $$mle(if exist \"$$T\" rd /S /Q \"$$T\")
distsrc.commands += $$mle(svn export $$_PRO_FILE_PWD_ \"$$T\")
distsrc.commands += $$mle(del /F /Q qsseditor-$${VERSION}.zip)
distsrc.commands += $$mle($$ZIP a -r -tzip -mx=9 qsseditor-$${VERSION}.zip \"$$T\")
distsrc.commands += $$mle(rd /S /Q \"$$T\")
QMAKE_EXTRA_TARGETS += distsrc
# portable binary
T="$${OUT_PWD}/qsseditor-portable-$$VERSION"
distbin.commands += $$mle(if exist \"$$T\" rd /S /Q \"$$T\")
distbin.commands += $$mle(mkdir \"$$T\")
distbin.commands += $$mle(mkdir \"$$T/platforms\")
distbin.commands += $$mle(mkdir \"$$T/imageformats\")
distbin.commands += $$mle(mkdir \"$$T/translations\")
# binary & necessary files
distbin.commands += $$mle(copy /y \"$${OUT_PWD}/$(DESTDIR_TARGET)\" \"$$T\")
for(ql, QTLIBS) {
distbin.commands += $$mle(copy /y \"$$[QT_INSTALL_BINS]\\$$ql\" \"$$T\")
}
for(qp, QTPLATFORMS) {
distbin.commands += $$mle(copy /y \"$$[QT_INSTALL_PLUGINS]\\platforms\\$$qp\" \"$$T/platforms\")
}
for(ml, MINGWLIBS) {
distbin.commands += $$mle(copy /y \"$$GCCDIR\\$$ml\" \"$$T\")
}
for(ip, IMAGEPLUGINS) {
distbin.commands += $$mle(copy /y \"$$[QT_INSTALL_PLUGINS]\\imageformats\\$$ip\" \"$$T/imageformats\")
}
# translations
distbin.commands += $$mle(copy /y \"$$TRANSLATIONS_DIR\\*.qm\" \"$$T/translations\")
distbin.commands += $$mle(copy /y \"$$TRANSLATIONS_DIR\\*.png\" \"$$T/translations\")
distbin.commands += $$mle(copy /y \"$$TRANSLATIONS_DIR\\translations.conf\" \"$$T/translations\")
for(l, LANGUAGES) {
qtl=$$[QT_INSTALL_TRANSLATIONS]\\qt_$${l}.qm $$[QT_INSTALL_TRANSLATIONS]\\qtbase_$${l}.qm
for(l, qtl) {
exists($$l) {
distbin.commands += $$mle(copy /y \"$$l\" \"$$T/translations\")
}
}
}
for(lc, LICENSES) {
distbin.commands += $$mle(copy /y \"$${_PRO_FILE_PWD_}\\$$lc\" \"$$T\")
}
# compress
distbin.commands += $$mle(del /F /Q qsseditor-portable-$${VERSION}$${HOST64}.zip)
distbin.commands += $$mle($$ZIP a -r -tzip -mx=9 qsseditor-portable-$${VERSION}$${HOST64}.zip \"$$T\")
distbin.commands += $$mle(rd /S /Q \"$$T\")
QMAKE_EXTRA_TARGETS += distbin
} else {
warning("7Z is not found, will not create custom dist targets")
}
INNO_APPID="{{A51E7AC1-A31C-40E7-82B3-D1DF32402DF8}"
exists($$INNO) {
message("Inno Setup is found, will create a setup file in a custom dist target")
LANGS=$$system(dir /B \"$$INNO\\..\\Languages\")
ISS="qsseditor-$${VERSION}.iss"
iss.commands += $$mle(echo $${LITERAL_HASH}define MyAppName \"QSS Editor\" > $$ISS)
iss.commands += $$mle(echo $${LITERAL_HASH}define MyAppPublisher \"Dmitry Baryshev\" >> $$ISS)
iss.commands += $$mle(echo $${LITERAL_HASH}define MyAppURL \"$$HTTPROOT\" >> $$ISS)
iss.commands += $$mle(echo [Setup] >> $$ISS)
!isEmpty(HOST64) {
iss.commands += $$mle(echo ArchitecturesAllowed=x64 >> $$ISS)
iss.commands += $$mle(echo ArchitecturesInstallIn64BitMode=x64 >> $$ISS)
}
iss.commands += $$mle(echo AppId=$$INNO_APPID >> $$ISS)
iss.commands += $$mle(echo AppName={$${LITERAL_HASH}MyAppName} >> $$ISS)
iss.commands += $$mle(echo AppVersion=$$VERSION >> $$ISS)
iss.commands += $$mle(echo AppPublisher={$${LITERAL_HASH}MyAppPublisher} >> $$ISS)
iss.commands += $$mle(echo AppPublisherURL={$${LITERAL_HASH}MyAppURL} >> $$ISS)
iss.commands += $$mle(echo AppSupportURL={$${LITERAL_HASH}MyAppURL}/wiki/discussion >> $$ISS)
iss.commands += $$mle(echo AppUpdatesURL={$${LITERAL_HASH}MyAppURL} >> $$ISS)
iss.commands += $$mle(echo DefaultDirName={pf}\\{$${LITERAL_HASH}MyAppName} >> $$ISS)
iss.commands += $$mle(echo DefaultGroupName={$${LITERAL_HASH}MyAppName} >> $$ISS)
iss.commands += $$mle(echo LicenseFile=$${_PRO_FILE_PWD_}\\LICENSE.txt >> $$ISS)
iss.commands += $$mle(echo OutputDir=. >> $$ISS)
iss.commands += $$mle(echo OutputBaseFilename=qsseditor-setup-$${VERSION}$${HOST64} >> $$ISS)
iss.commands += $$mle(echo SetupIconFile=$${_PRO_FILE_PWD_}\\images\\qsseditor.ico >> $$ISS)
iss.commands += $$mle(echo Compression=lzma >> $$ISS)
iss.commands += $$mle(echo SolidCompression=yes >> $$ISS)
iss.commands += $$mle(echo UninstallDisplayName={$${LITERAL_HASH}MyAppName} >> $$ISS)
iss.commands += $$mle(echo UninstallDisplayIcon={app}\\$${TARGET}.exe >> $$ISS)
iss.commands += $$mle(echo MinVersion="0,5.1" >> $$ISS)
!isEmpty(SIGNTOOL):exists($$CERT) {
iss.commands += $$mle(echo SignTool=bps sign /d \$\$qQSS Editor\$\$q /du \$\$q$$HTTPROOT\$\$q /f \$\$q$$CERT\$\$q /tr \$\$q$$RFC3161_SERVER\$\$q /v \$\$q\$\$f\$\$q >> $$ISS)
}
iss.commands += $$mle(echo [Languages] >> $$ISS)
for(lng, LANGS) {
lng = $$find(lng, .isl$)
!isEmpty(lng) {
lngname=$$lng
lngname ~= s/\\./x
exists($${_PRO_FILE_PWD_}\\isl\\$$lng) {
F=,$${_PRO_FILE_PWD_}\\isl\\$$lng
} else {
F=
}
iss.commands += $$mle(echo Name: \"$$lngname\"; MessagesFile: \"compiler:Languages\\$$lng$$F\" >> $$ISS)
}
}
iss.commands += $$mle(echo [Tasks] >> $$ISS)
iss.commands += $$mle(echo Name: \"desktopicon\"; Description: \"{cm:CreateDesktopIcon}\"; GroupDescription: \"{cm:AdditionalIcons}\" >> $$ISS)
iss.commands += $$mle(echo Name: \"quicklaunchicon\"; Description: \"{cm:CreateQuickLaunchIcon}\"; GroupDescription: \"{cm:AdditionalIcons}\"; OnlyBelowVersion: "0,6.1" >> $$ISS)
iss.commands += $$mle(echo [Files] >> $$ISS)
iss.commands += $$mle(echo Source: \"$${OUT_PWD}/$(DESTDIR_TARGET)\"; DestDir: \"{app}\"; Flags: ignoreversion >> $$ISS)
for(lc, LICENSES) {
iss.commands += $$mle(echo Source: \"$${_PRO_FILE_PWD_}\\$$lc\"; DestDir: \"{app}\"; Flags: ignoreversion >> $$ISS)
}
iss.commands += $$mle(echo Source: \"$$TRANSLATIONS_DIR/*.qm\"; DestDir: \"{app}/translations\"; Flags: ignoreversion >> $$ISS)
iss.commands += $$mle(echo Source: \"$$TRANSLATIONS_DIR/*.png\"; DestDir: \"{app}/translations\"; Flags: ignoreversion >> $$ISS)
iss.commands += $$mle(echo Source: \"$$TRANSLATIONS_DIR/translations.conf\"; DestDir: \"{app}/translations\"; Flags: ignoreversion >> $$ISS)
for(l, LANGUAGES) {
qtl=$$[QT_INSTALL_TRANSLATIONS]\\qt_$${l}.qm $$[QT_INSTALL_TRANSLATIONS]\\qtbase_$${l}.qm
for(l, qtl) {
exists($$l) {
iss.commands += $$mle(echo Source: \"$$l\"; DestDir: \"{app}/translations\"; Flags: ignoreversion >> $$ISS)
}
}
}
for(ql, QTLIBS) {
iss.commands += $$mle(echo Source: \"$$[QT_INSTALL_BINS]\\$$ql\"; DestDir: \"{app}\"; Flags: ignoreversion >> $$ISS)
}
for(qp, QTPLATFORMS) {
iss.commands += $$mle(echo Source: \"$$[QT_INSTALL_PLUGINS]\\platforms\\$$qp\"; DestDir: \"{app}\\platforms\"; Flags: ignoreversion >> $$ISS)
}
for(ip, IMAGEPLUGINS) {
iss.commands += $$mle(echo Source: \"$$[QT_INSTALL_PLUGINS]\\imageformats\\$$ip\"; DestDir: \"{app}\\imageformats\"; Flags: ignoreversion >> $$ISS)
}
for(ml, MINGWLIBS) {
iss.commands += $$mle(echo Source: \"$$GCCDIR\\$$ml\"; DestDir: \"{app}\"; Flags: ignoreversion >> $$ISS)
}
iss.commands += $$mle(echo [Icons] >> $$ISS)
iss.commands += $$mle(echo Name: \"{group}\\{$${LITERAL_HASH}MyAppName}\"; Filename: \"{app}\\$${TARGET}.exe\" >> $$ISS)
iss.commands += $$mle(echo Name: \"{group}\\{cm:UninstallProgram","{$${LITERAL_HASH}MyAppName}}\"; Filename: \"{uninstallexe}\" >> $$ISS)
iss.commands += $$mle(echo Name: \"{commondesktop}\\{$${LITERAL_HASH}MyAppName}\"; Filename: \"{app}\\$${TARGET}.exe\"; Tasks: desktopicon >> $$ISS)
iss.commands += $$mle(echo Name: \"{userappdata}\\Microsoft\\Internet Explorer\\Quick Launch\\{$${LITERAL_HASH}MyAppName}\"; Filename: \"{app}\\$${TARGET}.exe\"; Tasks: quicklaunchicon >> $$ISS)
iss.commands += $$mle(echo [Run] >> $$ISS)
iss.commands += $$mle(echo Filename: \"{app}\\$${TARGET}.exe\"; Description: \"{cm:LaunchProgram","{$${LITERAL_HASH}StringChange(MyAppName"," \'&\'"," \'&&\')}}\"; Flags: nowait postinstall skipifsilent >> $$ISS)
iss.commands += $$mle(echo ;Filename: \"{$${LITERAL_HASH}MyAppURL}/wiki/changelog\"; Flags: nowait shellexec >> $$ISS)
iss.commands += $$mle(echo [Code] >> $$ISS)
iss.commands += $$mle(echo procedure CurStepChanged(CurStep: TSetupStep); >> $$ISS)
iss.commands += $$mle(echo var >> $$ISS)
iss.commands += $$mle(echo ResultCode: Integer; >> $$ISS)
iss.commands += $$mle(echo Uninstall: String; >> $$ISS)
iss.commands += $$mle(echo UninstallQuery : String; >> $$ISS)
iss.commands += $$mle(echo begin >> $$ISS)
iss.commands += $$mle(echo UninstallQuery := ExpandConstant(\'Software\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\{$${LITERAL_HASH}emit SetupSetting(\"AppId\")}_is1\'); >> $$ISS)
iss.commands += $$mle(echo if (CurStep = ssInstall) then begin >> $$ISS)
iss.commands += $$mle(echo if RegQueryStringValue(HKLM, UninstallQuery, \'UninstallString\', Uninstall) >> $$ISS)
iss.commands += $$mle(echo or RegQueryStringValue(HKCU, UninstallQuery, \'UninstallString\', Uninstall) then begin >> $$ISS)
iss.commands += $$mle(echo if not Exec(RemoveQuotes(Uninstall), \'/VERYSILENT\', \'\', SW_SHOWNORMAL, ewWaitUntilTerminated, ResultCode) then begin >> $$ISS)
iss.commands += $$mle(echo MsgBox(SysErrorMessage(ResultCode), mbCriticalError, MB_OK); >> $$ISS)
iss.commands += $$mle(echo Abort(); >> $$ISS)
iss.commands += $$mle(echo end; >> $$ISS)
iss.commands += $$mle(echo end; >> $$ISS)
iss.commands += $$mle(echo end; >> $$ISS)
iss.commands += $$mle(echo end; >> $$ISS)
QMAKE_EXTRA_TARGETS += iss
QMAKE_EXTRA_TARGETS *= distbin
!isEmpty(SIGNTOOL):exists($$CERT) {
ADD="\"/sbps=$$SIGNTOOL \$\$p\""
}
distbin.depends += iss
distbin.commands += $$mle(\"$$INNO\" /o. $$ADD \"$$ISS\")
distbin.commands += $$mle(del /F /Q \"$$ISS\")
} else {
warning("Inno Setup is not found, will not create a setup file in a custom dist target")
}