screenlist.seq

; SCREENSHOT64 BY LUTZ BELLMANN

; --------------------------------------
; --------------------------------------
; PRESS F7 FOR MAKING THE SCREENSHOT
; --------------------------------------

; KERNAL ROUTINES
; ------------------

IOINIT   = $FF84
CINT     = $FF81
SETNAM   = $FFBD
SETLFS   = $FFBA
SETMSG   = $FF90
SAVE     = $FFD8
OPEN     = $FFC0
GETIN    = $FFE4
CHROUT   = $FFD2
CHRIN    = $FFCF

; POINTERS
; ------------------

POINT1   = $FB
POINT2   = $FD

; DATA
;-------------------

FNAME    = $02A7
BUFFER   = $02F0
FNAMELEN = $02F1
FINDEX   = $02F2
HIGHMEM  = $C000
EXTCOL   = $D020

         *= $0801
         .WORD SETUP-2,2018
         .BYTE $9E
         .TEXT " 2063:"
         .BYTE $00,$00,$00


SETUP    JSR CINT
         LDX #MCODELEN
LOOP0    LDA MCODE0,X ; MOVE INTERRUPT
         STA MCODE,X  ; TO HIMEM
         DEX
         BPL LOOP0
         LDX #$00
LOOP3    LDA INFOMSG,X ; PRINT INFO
         JSR CHROUT    ; MESSAGE
         INX
         CPX #INFOMSGLEN
         BNE LOOP3
         LDX #$00
LOOP1    LDA GETFILE,X ; PRINT WELCOME
         JSR CHROUT    ; MESSAGE
         INX
         CPX #GETFILELEN
         BNE LOOP1
         LDA #$00
         LDY #$00
LOOP2    JSR CHRIN    ; GET FILENAME
         STA FNAME,Y  ; FROM USER
         INY
         CMP #13
         BNE LOOP2
         DEY      ; CLEAR CARRIAGE RET
         CPY #9    ; TRUNCATE FILELEN
         BCC NOT0   ; GREATER THAN 9
         LDY #9
NOT0     LDA #"-"    ; APPEND INDEX
         STA FNAME,Y
         INY
         LDA #"0"
         STA FNAME,Y
         INY
         STY FNAMELEN; SAVE FNAME LEN
         LDA #"0"  ; SET FILEINDEX
         STA FINDEX   ; TO 0
         SEI        ; DISABLE INTERRUPTS
         LDA #<ISR  ; CHG INTERRUPT
         STA $0314
         LDA #>ISR
         STA $0315
         CLI        ; ENABLE INTERRUPTS
         RTS

; TEXT PASSAGE
; -----------------
GETFILE  = *
         .TEXT "ENTER FILENAME: "
GETFILELEN = *-GETFILE

; ---------

INFOMSG  = *
         .TEXT "SCREENSHOT64 V1.1 BY"
         .TEXT " LUTZ BELLMANN"
         .BYTE 13
         .TEXT "-F7 -> SAVE SCREEN &"
         .TEXT " EXIT"
         .BYTE 13
         .TEXT "-F5 -> SAVE SCREEN &"
         .TEXT " CONTINUE"
         .BYTE 13
         .TEXT "-R/S,RESTORE -> BREAK"
         .BYTE 13
INFOMSGLEN = *-INFOMSG

; SAVE $400-$7E8 TO DISK
;-----------------------
MCODE0   = *
MCODE    .OFFS $C000-MCODE0

SAVESCR  LDA #<$EA31 ; STD VEKTOR
         STA $0314
         LDA #>$EA31 ; WIEDERHERSTELLEN
         STA $0315

SAVECNT  LDA BUSY   ; TASTE GERADE ERST
         CMP #$01
         BEQ BREAK   ; GEDRUECKT? ABBR.
         LDA #$01
         STA BUSY   ; BUSY FLAG SETZEN
         STA EXTCOL ; WEISSER RAND
         LDY FNAMELEN; FILE INDEX
         DEY
         INC FINDEX   ; ERHOEHEN
         LDA FINDEX
         STA FNAME,Y  ; IN DATEINAMEN
         LDA #$00
         JSR SETMSG ; NO KERNAL MESS
         LDA #120
         STA $CD    ; DELAY CURSOR
         LDA FNAMELEN
         LDX #<FNAME  ; POINTER TO
         LDY #>FNAME  ; FILENAME
         JSR SETNAM   ; SET FILENAME
         LDA #$01
         LDX $BA    ; CURR. DEV. NO
         LDY #$FF
         JSR SETLFS   ; SET Ä# AND FILE
         LDA #$00
         STA POINT1
         LDA #$04
         STA POINT1+1 ;POINTER TO VICSCR
         LDA #POINT1
         LDX #$E8
         LDY #$07
         JSR SAVE   ; SAVE TO DISK
         LDA #14
         STA EXTCOL ; RESTORE COLOR
BREAK    LDA $DC0D     ; INTERRUPT BEST.
         PLA   ; ALLES VOM
         TAY          ; STAPEL HOLEN
         PLA
         TAX
         PLA
         RTI   ; RETURN FROM IRQ

; MODIFIED IRQ ROUTINE
; ----------------------

ISR      LDA $CB     ; READ KEY MATRIX
         CMP #$03    ; F7 PRESSED?
         BNE NOT1
         JMP SAVESCR
NOT1     CMP #$06    ; F5 PRESSED
         BNE NOT2
         LDA BUSY
         CMP #$01
         BEQ NOT3
         JMP SAVECNT
NOT2     LDA #$00   ; CLEAR
         STA BUSY   ; BUSY FLAG
NOT3     JMP $EA31    ; JMP STANDARD ÉÒÑ

BUSY     = *
         .BYTE $00
MCODELEN = *-MCODE