build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:8.0.2'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        // This was was added to address an issue in JCenter with some Android packages (https://stackoverflow.com/questions/50563338/could-not-find-runtime-jar-android-arch-lifecycleruntime1-0-0/50564224).
        // JCenter is no longer used but keep it just in case.
        maven { url "https://maven.google.com" }

        // Apparently needed by AndroidX dependencies
        maven { url "https://jitpack.io" }

        // Needed to get google-vr dependencies
        maven { url 'https://repo.gradle.org/gradle/libs-releases' }

        mavenCentral()
        google()
    }

    // Set Java compatibility for all projects
    plugins.withType(JavaPlugin).configureEach {
        java {
            toolchain {
                languageVersion = JavaLanguageVersion.of(17)
            }
        }
    }

    // Set Android compatibility for all Android projects
    plugins.withType(com.android.build.gradle.BasePlugin).configureEach {
        android {
            compileSdkVersion 33
            compileOptions {
                sourceCompatibility JavaVersion.VERSION_17
                targetCompatibility JavaVersion.VERSION_17
            }
        }
    }
}

tasks.register('clean', Delete) {
    delete rootProject.buildDir
}