Can't use mksafe on input.http when using the branch for v2.0.1

[Vaalyn]

Describe the bug
When using mksafe on an input.http Liquidsoap throws the following error:

At /var/azuracast/.opam/4.12.0/lib/liquidsoap/share/liquidsoap/git/43aa734d/libs/source.liq, line 1 char 0 - line 28 char 135:
Error 7: Invalid value:
This source may control its own latency and cannot be used with this operator.

This problem is btw. also happening when I'm not using mksafe, it is then complaining about the same problem but referencing libs/telnet.liq:

At /var/azuracast/.opam/4.12.0/lib/liquidsoap/share/liquidsoap/git/43aa734d/libs/telnet.liq, line 96 char 0 - line 28 char 110:
Error 7: Invalid value:
This source may control its own latency and cannot be used with this operator.

To Reproduce
This is the input.http I'm using:

playlist_test_extern = mksafe(input.http(max_buffer=10., "https://radio.bronyradiogermany.com/radio/8030/test-stream"))

Expected behavior
Liquidsoap should not throw an error on input.http using mksafe and other operators.

Version details

• OS: Ubuntu 20.04
• Version: v2.0.1 branch at commit 43aa734

Install method
Opam / Build from GH repo, see https://github.com/AzuraCast/docker-azuracast-radio/blob/main/Dockerfile#L41-L48

[toots]

Are you redefining input.http? This works fine here on the latest branch:

% liquidsoap 'output.dummy(mksafe(input.http("foo")))'
2021/11/09 15:39:59 >>> LOG START
2021/11/09 15:39:59 [main:3] Liquidsoap 2.0.1+git@43aa734d

[Vaalyn]

I don't think that we redefine it by ourself 🤔

At least I can't see any def replaces in our generated script and we don't have any imports in the script so (I think) we completely rely on what's provided by the LS installation.

The only def replaces input.http I could find via a grep on the whole server was in the following file (this one on the LS GH repo):

/var/azuracast/.opam/4.12.0/lib/liquidsoap/share/liquidsoap/git/43aa734d/libs/telnet.liq

Which contains:

%ifdef input.gstreamer.audio_video
# @docof input.gstreamer.audio_video
def replaces input.gstreamer.audio_video(%argsof(input.gstreamer.audio_video)) =
  s = input.gstreamer.audio_video(%argsof(input.gstreamer.audio_video))

  server.register(namespace=s.id(), description="Set gstreamer pipeline state to play",
                  "play", fun (_) -> try
                    s.play()
                    "Done."
                  catch err do
                    "Error while setting state to play: #{err}"
                  end)

  server.register(namespace=s.id(), description="Set gstreamer pipeline state to paused",
                  "pause", fun (_) -> try
                    s.pause()
                    "Done."
                  catch err do
                    "Error while setting state to paused: #{err}"
                  end)

  server.register(namespace=s.id(), description="Restart gstreamer pipeline",
                  "restart", fun (_) -> try
                    s.restart()
                    "Done."
                  catch err do
                    "Error while restarting pipeline: #{err}"
                  end)

  s
end
%endif

# @docof blank.strip
def replaces blank.strip(%argsof(blank.strip), s) =
  s = blank.strip(%argsof(blank.strip), s)

  server.register(namespace=s.id(), description="Check if the source is stripping.",
                  "is_stripping", fun (_) -> begin
                    "#{s.is_blank()}"
                  end)

  s
end

# @docof output.external
def replaces output.external(%argsof(output.external), f, p, s) =
  s = output.external(%argsof(output.external), f, p, s)

  server.register(namespace=s.id(), description="Re-open the output.",
                  "reopen", fun (_) -> begin
                    s.reopen()
                    "Done."
                  end)

  s
end

# @docof input.external.avi
def replaces input.external.avi(%argsof(input.external.avi), s) =
  s = input.external.avi(%argsof(input.external.avi), s)

  server.register(namespace=s.id(), description="Show internal buffer length (in seconds).",
                  "buffer_length", fun (_) -> begin
                    let (audio, video, total) = s.buffer_length()
                    "audio buffer length: #{audio}\nvideo buffer length: #{video}\ntotal buffer length: #{total}"
                  end)

  s
end

# @docof input.harbor
def replaces input.harbor(%argsof(input.harbor), s) =
  s = input.harbor(%argsof(input.harbor), s)

  server.register(namespace=s.id(), description="Stop current source client, if connected.",
                  "stop", fun (_) -> begin
                    s.stop()
                    "Done"
                  end)

  server.register(namespace=s.id(), description="Display current status.",
                  "status", fun (_) -> begin
                    s.status()
                  end)

  server.register(namespace=s.id(), description="Get the buffer's length, in seconds.",
                  "buffer_length", fun (_) -> begin
                    "#{s.buffer_length()}"
                  end)

  s
end

%ifdef input.http
# @docof input.http
def replaces input.http(%argsof(input.http), s) =
  s = input.http(%argsof(input.http), s)

  server.register(namespace=s.id(), description="Start the source, if needed.",
                  "start", fun (_) -> begin
                    s.start()
                    "Done!"
                  end)

  server.register(namespace=s.id(), description="Stop the source if connected.",
                  "stop", fun (_) -> begin
                    s.stop()
                    "Done!"
                  end)

  server.register(namespace=s.id(), description="Get or set the stream's HTTP URL. Setting a new URL will not affect an ongoing connection.",
                  usage="url [url]", "url", fun (url) -> begin
                    if url == "" then
                      s.url()
                    else begin
                      s.set_url({url})
                      "Done!"
                    end end
                  end)

  server.register(namespace=s.id(), description="Return the current status of the source, either \"stopped\" \
                                                 (the source isn't trying to relay the HTTP stream), \"polling\" \
                                                 (attempting to connect to the HTTP stream) or \"connected <url>\" \
                                                 (connected to <url>, buffering or playing back the stream).",
                  "status", fun (_) -> begin
                    s.status()
                  end)

  server.register(namespace=s.id(), description="Get the buffer's length, in seconds.",
                  "buffer_length", fun (_) -> begin
                    "#{s.buffer_length()}"
                  end)

  s
end
%endif

[toots]

Ok. Do you have a minimal script that reproduces the issue?

[Vaalyn]

Ok. Do you have a minimal script that reproduces the issue?

Will get you a minimal script tomorrow 👍

Edit 1 day later:
Didn't manage to work on the minimal script today.

[Vaalyn]

Here is a minimal script that still causes the error when I use it:

init.allow_root.set(true)
init.daemon.set(false)
log.stdout.set(true)
log.file.set(false)

playlist_remote_playlist = mksafe(input.http(max_buffer=10., "https://radio.bronyradiogermany.com/radio/8030/test-stream"))
playlist_remote_playlist = cue_cut(id="cue_playlist_remote_playlist", playlist_remote_playlist)

radio = random(id="standard_playlists", weights=[3], [playlist_remote_playlist])

output.dummy(radio)

I further tried to simplify the script and it seems like the following line is causing the error. When I remove it it starts up without the error:

playlist_remote_playlist = cue_cut(id="cue_playlist_remote_playlist", playlist_remote_playlist)

[toots]

Hi,

This is expected! input.http is a live source, meaning that it receives its data from a live source and, as such, it cannot be accelerated.

The cue_cut operator requires full control over the source, to fast forward to the cue-in points so it cannot work with input.http.

If you need to use cue_cut on a remote playlist, I believe that the playlist operator should be good for that kind of use-case.

I'm moving this to a conversation so it can be read and used by other users. Let us know if we can help further.

[gammaw]

Hi!

I'm having a similar issue. I'd like to add an external stream to a switch because I'd like to schedule when the stream is relayed, but switch doesn't seem to accept such a source (I'm getting the the error message above). Any idea how this can be done?

Thanks!

[gammaw]

Just found one working solution in Azuracast's code generator (v0.17.3):

external_source_for_switch = mksafe(buffer(buffer=5., input.http(url))