Update on dynamic stream issues in 2.0.2

[theotherjenkutler]

Hi @toots
Hope you had a nice weekend. I wanted to just give you an update on the dynamic stream situation.

It appears that source.shutdown still doesn't work. I am unsure of what the issue is. If I replace the source.shutdown function with just shutdown() the script ends as would be expected. It is some kind of bug specific to being able to shut down an active source.

Here is the code that I am working from:

#!/home/jenkutler/.opam/4.10.0/bin/liquidsoap

settings.init.force_start.set(true) #this will allow LS to start w/o an active source
settings.server.telnet.set(true) #starts telnet server

set("log.file",false)
#set("log.file.path", "/home/jenkutler/ls_logs/measures.log")
set("log.stdout",true)
set("log.level",5)

# First, we create a list referencing the dynamic sources:
dyn_sources = ref([])

#esp32 must send a message over telnet formatted as:
#"mac 000000000000.mp3" the telnet server will register
#the mountpoint as 000000000000.mp3 automatically
def on_telconnect(m)
    identifierstring = ""
    i = ref(identifierstring)
    i := (m)
    log.debug(!i)
    # The playlist source 
    uri = "/home/jenkutler/audio/"
    s = playlist(uri)
    # The output
    out = output.icecast(%mp3(samplerate = 44100, internal_quality=1),
    host = "localhost", port = 8000,
    password = "measures", mount = !i,
    s,
    fallible = true)

    # We register both source and output 
    # in the list of sources
    dyn_sources := 
        list.append( [(uri,s)],
                    !dyn_sources)

    list.iter(fun(n) -> print(newline = true, n), !dyn_sources)
    
    trackbool = true
    trackplayed = ref(trackbool)


    def handlemetadata(m)
        log.debug("handling metadata")
        if !trackplayed then
            log.debug("print info to file")
            trackplayed := false
        else
            log.debug("handling the end")
            def parse_list(ret, current_element) = 
                log.debug("parse_list called")
                # ret is of the form: (matching_sources, remaining_sources)
                # We extract those two:
                matching_sources = fst(ret)
                remaining_sources = snd(ret)

                # current_element is of the form: ("uri", source) so 
                # we check the first element
                current_uri = fst(current_element)
                if current_uri == uri then
                    # In this case, we add the source to the list of
                    # matched sources
                    (list.append( [snd(current_element)], 
                             matching_sources),
                            remaining_sources)
                else
                    # In this case, we put the element in the list of remaining
                    # sources
                    (matching_sources,
                    list.append([current_element], 
                                remaining_sources))
                end
            end    
    
            # Now we execute the function:
            result = list.fold(parse_list, ([], []), !dyn_sources)
            matching_sources = fst(result)
            remaining_sources = snd(result)

            # We store the remaining sources in dyn_sources
            dyn_sources := remaining_sources

            # If no source matched, we return an error
            if list.length(matching_sources) == 0 then
                log.debug("Error: no matching sources!")
            else
                # We stop all sources
                log.debug("We stop all sources")
                s.shutdown()
                list.iter(source.shutdown, matching_sources)
                # And return
            
            end
        end       
    end
    source.on_metadata(s, handlemetadata)

    "Done"
end
server.register(usage= "mac <mac>",
                "mac", on_telconnect)

Any help is greatly appreciated as always.

[toots]

Hi! I'm just getting out of a time hole here. Will look at it shortly.

[toots]

Ok, I think I got to the bottom of it. One of the simplification we did with 2.0.x was to remove the notion of active source vs. source. An active source, internally, is a source that needs to be animated by the internal clock, typically an output but, also, inputs such as input.alsa, input.srt and etc.

Active sources had a different type than sources even though, for all intent and purposes, we thought, they should be the same for liquidsoap users.

Well, this wasn't correct w.r.t. shutdown because only active sources can actually be shutdown. All other sources are animated by their output and are implicitly shutdown when all the outputs using them are eliminated.

I have pushed a fix to v2.0.4-preview and main that fixes this situation. Now, only sources that can be shutdown have a shutdown() method and the generic source.shutdown is removed. This means that you should only be able to call shutdown when it is actually effective.

To come back to your script, all that you should have to do is replace s.shutdown() by out.shutdown(). Also, since you are keeping the output in the closure of the function, you do not need to register a list of sources:

#!/home/jenkutler/.opam/4.10.0/bin/liquidsoap

settings.init.force_start.set(true) #this will allow LS to start w/o an active source
settings.server.telnet.set(true) #starts telnet server

set("log.file",false)
#set("log.file.path", "/home/jenkutler/ls_logs/measures.log")
set("log.stdout",true)
set("log.level",5)

#esp32 must send a message over telnet formatted as:
#"mac 000000000000.mp3" the telnet server will register
#the mountpoint as 000000000000.mp3 automatically
def on_telconnect(m)
    identifierstring = ""
    i = ref(identifierstring)
    i := (m)
    log.debug(!i)
    # The playlist source 
    uri = "/home/jenkutler/audio/"
    s = playlist(uri)
    # The output
    out = output.icecast(%mp3(samplerate = 44100, internal_quality=1),
    host = "localhost", port = 8000,
    password = "measures", mount = !i,
    s,
    fallible = true)
    
    trackbool = true
    trackplayed = ref(trackbool)

    def handlemetadata(m)
        log.debug("handling metadata")
        if !trackplayed then
            log.debug("print info to file")
            trackplayed := false
        else
            log.debug("handling the end")
            out.shutdown()
        end       
    end
    source.on_metadata(s, handlemetadata)

    "Done"
end
server.register(usage= "mac <mac>",
                "mac", on_telconnect)