build.gradle

plugins {
    id "com.github.johnrengelman.shadow" version "5.2.0" apply false
    id "java"
    id "checkstyle"
    id "maven-publish"
    id "org.embulk.embulk-plugins" version "0.4.1"
    id "com.palantir.git-version" version "0.12.3"
}

repositories {
    mavenCentral()
    jcenter()
}

group = "io.trocco"
description = "Bigquery output for embulk"

version = {
    def vd = versionDetails()
    if (vd.commitDistance == 0 && vd.lastTag ==~ /^v[0-9]+\.[0-9]+\.[0-9]+(\.[a-zA-Z0-9]+)?/) {
        vd.lastTag.substring(1)
    } else {
        "0.0.0.${vd.gitHash}.pre"
    }
}()

sourceCompatibility = 1.8
targetCompatibility = 1.8

tasks.withType(JavaCompile) {
    options.compilerArgs << "-Xlint:deprecation" << "-Xlint:unchecked"
}

dependencies {
    compileOnly "org.embulk:embulk-core:0.9.23"

    compile project(path: ":shadow-google-cloud-bigquery-helper", configuration: "shadow")

    // compile "YOUR_JAR_DEPENDENCY_GROUP:YOUR_JAR_DEPENDENCY_MODULE:YOUR_JAR_DEPENDENCY_VERSION"
    testCompile "junit:junit:4.13"
    testCompile "org.slf4j:slf4j-simple:1.7.12"
    testCompile 'org.embulk:embulk-standards:0.9.23'
    testCompile 'org.embulk:embulk-test:0.9.23'
    testCompile "org.mockito:mockito-core:1.10.19"
    testCompile "org.embulk:embulk-core:0.9.23:tests"
    testCompile "org.embulk:embulk-deps-buffer:0.9.23"
    testCompile "org.embulk:embulk-deps-config:0.9.23"
}

embulkPlugin {
    mainClass = "org.embulk.output.bigquery_java.BigqueryJavaOutputPlugin"
    category = "output"
    type = "bigquery_java"
}

publishing {
    publications {
        embulkPluginMaven(MavenPublication) {  // Publish it with "publishEmbulkPluginMavenPublicationToMavenRepository".
            from components.java  // Must be "components.java". The dependency modification works only for it.
        }
    }
    repositories {
        maven {
            url = "${project.buildDir}/mavenPublishLocal"
        }
    }
}

checkstyle {
    configFile = file("${project.rootDir}/config/checkstyle/checkstyle.xml")
    toolVersion = '6.14.1'
}
checkstyleMain {
    configFile = file("${project.rootDir}/config/checkstyle/default.xml")
    ignoreFailures = true
}
checkstyleTest {
    configFile = file("${project.rootDir}/config/checkstyle/default.xml")
    ignoreFailures = true
}
task checkstyle(type: Checkstyle) {
    classpath = sourceSets.main.output + sourceSets.test.output
    source = sourceSets.main.allJava + sourceSets.test.allJava
}

gem {
    from("LICENSE")  // Optional -- if you need other files in the gem.
    authors = [ "giwa" ]
    email = [ "ugw.gi.world@gmail.com" ]
    // "description" of the gem is copied from "description" of your Gradle project.
    summary = "Bigquery output plugin for Embulk"
    homepage = "https://github.com/trocco-io/embulk-output-bigquery_java"
    licenses = [ "Apache-2.0" ]
}

gemPush {
    host = "https://rubygems.org"
}