build.gradle

plugins {
	id 'application'
}

repositories {
	mavenCentral()
	maven {
		url "https://plugins.gradle.org/m2/"
		url "https://jogamp.org/deployment/maven"
	}
}

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

import org.gradle.internal.os.OperatingSystem

project.ext.lwjglVersion = "3.3.4"
project.ext.jomlVersion = "1.10.8"

switch (OperatingSystem.current()) {
	case OperatingSystem.LINUX:
		project.ext.lwjglNatives = "natives-linux"
		def osArch = System.getProperty("os.arch")
		if (osArch.startsWith("arm") || osArch.startsWith("aarch64")) {
			project.ext.lwjglNatives += osArch.contains("64") || osArch.startsWith("armv8") ? "-arm64" : "-arm32"
		} else if  (osArch.startsWith("ppc")) {
			project.ext.lwjglNatives += "-ppc64le"
		} else if  (osArch.startsWith("riscv")) {
			project.ext.lwjglNatives += "-riscv64"
		}
		break
	case OperatingSystem.MAC_OS:
		project.ext.lwjglNatives = System.getProperty("os.arch").startsWith("aarch64") ? "natives-macos-arm64" : "natives-macos"
		break
	case OperatingSystem.WINDOWS:
		def osArch = System.getProperty("os.arch")
		project.ext.lwjglNatives = osArch.contains("64")
			? "natives-windows${osArch.startsWith("aarch64") ? "-arm64" : ""}"
			: "natives-windows-x86"
		break
}

dependencies {
	implementation "org.joml:joml:$jomlVersion"

	implementation platform("org.lwjgl:lwjgl-bom:$lwjglVersion")

	implementation "org.lwjgl:lwjgl"
	implementation "org.lwjgl:lwjgl-glfw"
	implementation "org.lwjgl:lwjgl-opengl"
	implementation "org.lwjgl:lwjgl-openal"
	implementation "org.lwjgl:lwjgl-stb"
	runtimeOnly "org.lwjgl:lwjgl::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-glfw::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-openal::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-opengl::$lwjglNatives"
	runtimeOnly "org.lwjgl:lwjgl-stb::$lwjglNatives"
}

sourceSets {
	main {
		java {
			srcDir 'src'
		}
		resources {
			srcDir 'res'
		}
	}
}

jar {
	manifest {
		attributes 'Main-Class': 'com.zandgall.plorpland.Main'
	}

	duplicatesStrategy = DuplicatesStrategy.EXCLUDE;

	from {
		configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
	}
}

task release(type: Copy) {
	dependsOn('linux-release:jar')
	dependsOn('macos-release:jar')
	dependsOn('windows-release:jar')
	from ("./linux-release/build/libs/linux-release.jar")
	from ("./macos-release/build/libs/macos-release.jar")
	from ("./windows-release/build/libs/windows-release.jar")
	into("release")
}

application {
	mainClass = 'com.zandgall.plorpland.Main'
}