app-metrics/nginx-lua-prometheus: migrate to lua-single.eclass

Pure-Lua module - but not really multi-impl because being used internally
by nginx, it must only be available for the LUA_SINGLE_TARGET of the latter.

Closes: https://bugs.gentoo.org/752561
Signed-off-by: Marek Szuba <[email protected]>

app-metrics/nginx-lua-prometheus/nginx-lua-prometheus-0.1_pre20170610-r100.ebuild

@@ -0,0 +1,39 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# This should be kept in sync with implementations supported
+# by www-servers/nginx
+LUA_COMPAT=( luajit )
+
+# This is the upstream tag which corresponds to this release.
+# It needs to be updated with every bump.
+TAG="0.1-20170610"
+
+inherit lua-single
+
+DESCRIPTION="Library that exports Nginx metrics to Prometheus"
+HOMEPAGE="https://github.com/knyar/nginx-lua-prometheus"
+SRC_URI="https://github.com/knyar/${PN}/archive/${TAG}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+COMMON_DEPEND="${LUA_DEPS}"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}
+	www-servers/nginx[nginx_modules_http_lua,${LUA_SINGLE_USEDEP}]"
+BDEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}-${TAG}"
+
+src_install() {
+	insinto "$(lua_get_lmod_dir)"/${PN}
+	doins prometheus.lua
+	dodoc *.md
+}

profiles/package.mask

@@ -447,6 +447,7 @@ kde-apps/kdebase-meta:5
 =app-editors/scite-4.4.4-r10
 >=app-editors/vim-8.2.0814-r100
 >=app-emulation/libguestfs-1.38.6-r100
+>=app-metrics/nginx-lua-prometheus-0.1_pre20170610-r100
 >=app-misc/worker-3.8.3-r100
 >=dev-games/cegui-0.8.7-r100
 =dev-games/openscenegraph-openmw-3.4_p20200425-r100