feat: Add pod-pinner to CAST AI onboarding (#44)

main.tf

@@ -244,6 +244,61 @@ resource "null_resource" "wait_for_cluster" {
   }
 }
 
+resource "helm_release" "castai_pod_pinner" {
+  name             = "castai-pod-pinner"
+  repository       = "https://castai.github.io/helm-charts"
+  chart            = "castai-pod-pinner"
+  namespace        = "castai-agent"
+  create_namespace = true
+  cleanup_on_fail  = true
+  wait             = true
+
+  set {
+    name  = "castai.clusterID"
+    value = castai_aks_cluster.castai_cluster.id
+  }
+
+  dynamic "set" {
+    for_each = var.api_url != "" ? [var.api_url] : []
+    content {
+      name  = "castai.apiURL"
+      value = var.api_url
+    }
+  }
+
+  set_sensitive {
+    name  = "castai.apiKey"
+    value = castai_aks_cluster.castai_cluster.cluster_token
+  }
+
+  dynamic "set" {
+    for_each = var.grpc_url != "" ? [var.grpc_url] : []
+    content {
+      name  = "castai.grpcURL"
+      value = var.grpc_url
+    }
+  }
+
+  dynamic "set" {
+    for_each = var.castai_components_labels
+    content {
+      name  = "podLabels.${set.key}"
+      value = set.value
+    }
+  }
+
+  set {
+    name  = "replicaCount"
+    value = "0"
+  }
+
+  depends_on = [helm_release.castai_agent]
+
+  lifecycle {
+    ignore_changes = [set, version]
+  }
+}
+
 resource "helm_release" "castai_spot_handler" {
   name             = "castai-spot-handler"
   repository       = "https://castai.github.io/helm-charts"

variables.tf

@@ -11,6 +11,12 @@ variable "castai_api_token" {
   default = ""
 }
 
+variable "grpc_url" {
+  type        = string
+  description = "gRPC endpoint used by pod-pinner"
+  default     = "grpc.cast.ai:443"
+}
+
 variable "aks_cluster_name" {
   type        = string
   description = "Name of the cluster to be connected to CAST AI."