feat: Varscan2 - SnpEff Meta wrapper

meta/bio/varscan2_snpeff/meta.yaml

@@ -0,0 +1,21 @@
+name: Varscan2 - SnpEff
+description: >
+  This meta-wrapper includes the following steps:
+
+    +----------------+----------+------------------------------------------------+
+    | Step           | Tool     | Reason                                         |
+    +================+==========+================================================+
+    | Get reference  | Ensembl | Acquire genome sequence                        |
+    +----------------+----------+------------------------------------------------+
+    | Call variants  | Samtools | Acquire a list of potential variants           |
+    +----------------+----------+------------------------------------------------+
+    | Call variants  | Varscan2 | Call variants with Varscan2                    |
+    +----------------+----------+------------------------------------------------+
+    | Annotate calls | SnpEff   | Download variants database                     |
+    +----------------+----------+------------------------------------------------+
+    | Annotate calls | SnpEff   | Annotate variants with downloaded database     |
+    +----------------+----------+------------------------------------------------+
+
+authors:
+  - Thibault Dayris
+

meta/bio/varscan2_snpeff/test/Snakefile

@@ -0,0 +1,75 @@
+rule get_genome_fasta:
+    output:
+        "genome.fasta",
+    threads: 1
+    log:
+        "logs/get_genome_fasta.log",
+    params:
+        species="saccharomyces_cerevisiae",
+        datatype="dna",
+        build="R64-1-1",
+        release="105",
+    wrapper:
+        "master/bio/reference/ensembl-sequence"
+
+
+rule samtools_mpileup:
+    input:
+        bam=expand(
+            "{sample}.sorted.bam",
+            sample=("a", "b"),
+        ),
+        reference_genome="genome.fasta",
+    output:
+        "samtools/mpileup.gz",
+    threads: 1
+    log:
+        "logs/samtools_mpileup.log",
+    params:
+        extra=" --count-orphans ",
+    wrapper:
+        "master/bio/samtools/mpileup"
+
+
+rule varscan2_somatic:
+    input:
+        mpileup="samtools/mpileup.gz",
+    output:
+        snp="varscan2/snp.vcf",
+        indel="varscan2/indel.vcf",
+    threads: 1
+    log:
+        "logs/varscan2_somatic.log",
+    params:
+        extra=" --strand-filter 1 ",
+    wrapper:
+        "master/bio/varscan/somatic"
+
+
+rule snpeff_download:
+    output:
+        directory("resources/snpeff/R64-1-1.105"),
+    threads: 1
+    log:
+        "logs/snpeff_download.log",
+    params:
+        reference="R64-1-1.105",
+    wrapper:
+        "master/bio/snpeff/download"
+
+
+rule snpeff_annotate:
+    input:
+        calls="varscan2/snp.vcf",
+        db="resources/snpeff/R64-1-1.105",
+    output:
+        calls="snpeff/annotated.vcf",
+        stats="snpeff/annotated.html",
+        csvstats="snpeff/annotated.csv",
+    threads: 1
+    log:
+        "logs/snpeff_annotate.log",
+    params:
+        extra=" -nodownload -noLog ",
+    wrapper:
+        "master/bio/snpeff/annotate"

meta/bio/varscan2_snpeff/used_wrappers.yaml

@@ -0,0 +1,6 @@
+wrappers:
+  - bio/reference/ensembl-sequence
+  - bio/samtools/mpileup
+  - bio/varscan/somatic
+  - bio/snpeff/download
+  - bio/snpeff/annotate

test_wrappers.py

@@ -836,6 +836,20 @@ def test_open_cravat_module(run):
     )
 
 
+def test_varscan2_snpeff_meta(run):
+    run(
+        "meta/bio/varscan2_snpeff",
+        [
+            "snakemake",
+            "--cores",
+            "1",
+            "--use-conda",
+            "-F",
+            "snpeff/annotated.vcf",
+        ],
+    )
+
+
 def test_salmon_tximport_meta(run):
     run(
         "meta/bio/salmon_tximport",