Add example of higher-order effect handler (DynamicReader)

bluefin-internal/src/Bluefin/Internal/Examples.hs

@@ -1021,3 +1021,42 @@ rethrowIOExample = runEff $ \io -> do
   effIO io $ putStrLn $ case r of
     Left e -> "Caught IOException:\n" ++ show e
     Right contents -> contents
+
+data DynamicReader r e = DynamicReader
+  { askLRImpl :: forall e'. Eff (e' :& e) r,
+    localLRImpl :: forall e' a. (r -> r) -> Eff e' a -> Eff (e' :& e) a
+  }
+
+instance Handle (DynamicReader r) where
+  mapHandle h =
+    DynamicReader
+      { askLRImpl = useImplUnder (askLRImpl h),
+        localLRImpl = \f k -> useImplUnder (localLRImpl h f k)
+      }
+
+askLR ::
+  (e :> es) =>
+  DynamicReader r e ->
+  Eff es r
+askLR c = makeOp (askLRImpl (mapHandle c))
+
+localLR ::
+  (e :> es) =>
+  DynamicReader r e ->
+  (r -> r) ->
+  Eff es a ->
+  Eff es a
+localLR c f m = makeOp (localLRImpl (mapHandle c) f m)
+
+runDynamicReader ::
+  r ->
+  (forall e. DynamicReader r e -> Eff (e :& es) a) ->
+  Eff es a
+runDynamicReader r k =
+  runReader r $ \h -> do
+    useImplIn
+      k
+      DynamicReader
+        { askLRImpl = ask h,
+          localLRImpl = \f k' -> makeOp (local h f (useImpl k'))
+        }