Interaction - Add "pass grenade" interaction

addons/interaction/CfgVehicles.hpp

@@ -68,6 +68,15 @@ class CfgVehicles {
                     };
                 };
 
+                class ACE_PassThrowable {
+                    displayName = CSTRING(PassThrowable);
+                    condition = QUOTE([ARR_3(_target,_player,(currentThrowable _player) param [ARR_2(0,'')])] call FUNC(canPassThrowable));
+                    statement = QUOTE([ARR_3(_target,_player,(currentThrowable _player) param [ARR_2(0,'')])] call FUNC(passThrowable));
+                    exceptions[] = {"isNotSwimming"};
+                    showDisabled = 0;
+                    modifierFunction = QUOTE(_this select 3 set [ARR_2(2,getText (configFile >> 'CfgMagazines' >> (currentThrowable (_this select 1)) param [ARR_2(0,'HandGrenade')] >> 'picture'))];); // Set picture of the current grenade
+                };
+
                 class ACE_TeamManagement {
                     displayName = CSTRING(TeamManagement);
                     condition = QUOTE([ARR_2(_player,_target)] call DFUNC(canJoinTeam) && {GVAR(EnableTeamManagement)});

addons/interaction/XEH_PREP.hpp

@@ -24,7 +24,9 @@ PREP(modifyTeamManagementAction);
 PREP(canJoinTeam);
 PREP(joinTeam);
 PREP(canPassMagazine);
+PREP(canPassThrowable);
 PREP(passMagazine);
+PREP(passThrowable);
 PREP(canBecomeLeader);
 PREP(doBecomeLeader);
 PREP(doRemoteControl);

addons/interaction/functions/fnc_canPassThrowable.sqf

@@ -0,0 +1,28 @@
+#include "..\script_component.hpp"
+/*
+ * Author: Timi007
+ * Checks if target unit can accept given throwable.
+ * Does not check if the throwable exists in the inventory of the player.
+ *
+ * Arguments:
+ * 0: Unit to pass the throwable to <OBJECT>
+ * 1: Unit that passes the throwable <OBJECT>
+ * 2: Throwable classname <STRING>
+ *
+ * Return Value:
+ * Unit can pass throwables <BOOL>
+ *
+ * Example:
+ * [_target, _player, "HandGrenade"] call ace_interaction_fnc_canPassThrowable
+ *
+ * Public: No
+ */
+
+params [["_target", objNull, [objNull]], ["_player", objNull, [objNull]], ["_throwable", "", [""]]];
+
+if (!GVAR(enableThrowablePassing)) exitWith {false};
+if (_throwable isEqualTo "") exitWith {false};
+if !(_target call EFUNC(common,isAwake)) exitWith {false};
+if ((!isNull objectParent _target) && {(vehicle _target) isNotEqualTo (vehicle _player)}) exitWith {false};
+
+[_target, _throwable] call CBA_fnc_canAddItem

addons/interaction/functions/fnc_passThrowable.sqf

@@ -0,0 +1,36 @@
+#include "..\script_component.hpp"
+/*
+ * Author: Timi007
+ * Pass throwable to another unit.
+ *
+ * Arguments:
+ * 0: Unit to pass the throwable to <OBJECT>
+ * 1: Unit that passes the throwable <OBJECT>
+ * 2: Throwable classname <STRING>
+ * 3: Play passing animation <BOOL> (default: true)
+ *
+ * Return Value:
+ * None
+ *
+ * Example:
+ * [_target, _player, "HandGrenade"] call ace_interaction_fnc_passThrowable
+ *
+ * Public: No
+ */
+
+params [["_target", objNull, [objNull]], ["_player", objNull, [objNull]], ["_throwable", "", [""]], ["_animate", true, [true]]];
+TRACE_4("Pass throwable params",_player,_target,_throwable,_animate);
+
+if (isNull _target) exitWith {ERROR("Target is null.")};
+if (isNull _player) exitWith {ERROR("Player is null.")};
+if (_throwable isEqualTo "") exitWith {ERROR("No throwable specified.")};
+if !([_target, _throwable] call CBA_fnc_canAddItem) exitWith {ERROR("Cannot add throwable to target due to lack of inventory space.")};
+
+if (_animate) then {[_player, "PutDown"] call EFUNC(common,doGesture)};
+
+_player removeItem _throwable;
+_target addItem _throwable;
+
+private _displayName = getText (configFile >> 'CfgMagazines' >> _throwable >> 'displayName');
+private _playerName = [_player] call EFUNC(common,getName);
+[QEGVAR(common,displayTextStructured), [[LSTRING(PassThrowableHint), _playerName, _displayName], 1.5, _target], [_target]] call CBA_fnc_targetEvent;

addons/interaction/initSettings.inc.sqf

@@ -21,6 +21,13 @@
     true
 ] call CBA_fnc_addSetting;
 
+[
+    QGVAR(enableThrowablePassing), "CHECKBOX",
+    LSTRING(PassThrowableSetting),
+    format ["ACE %1", LLSTRING(DisplayName)],
+    true
+] call CBA_fnc_addSetting;
+
 [
     QGVAR(disableNegativeRating), "CHECKBOX",
     [LSTRING(DisableNegativeRating_DisplayName), LSTRING(DisableNegativeRating_Description)],

addons/interaction/stringtable.xml

@@ -1260,6 +1260,18 @@
             <Chinesesimp>显示"给予弹匣"互动动作</Chinesesimp>
             <Chinese>顯示"給予彈匣"互動動作</Chinese>
         </Key>
+        <Key ID="STR_ACE_Interaction_PassThrowable">
+            <English>Pass grenade</English>
+            <German>Granate geben</German>
+        </Key>
+        <Key ID="STR_ACE_Interaction_PassThrowableHint">
+            <English>%1 passed you %2.</English>
+            <German>%1 hat dir %2 gegeben.</German>
+        </Key>
+        <Key ID="STR_ACE_Interaction_PassThrowableSetting">
+            <English>Show "pass grenade" interaction</English>
+            <German>Zeige "Granate geben" Interaktion</German>
+        </Key>
         <Key ID="STR_ACE_Interaction_PullOutBody">
             <English>Pull out body</English>
             <German>Person herausziehen</German>

docs/wiki/feature/interaction.md

@@ -45,3 +45,6 @@ Some of the zeus actions are also available (while in zeus) in the interaction m
  - Open the interaction menu.
  - Select `Waypoints`.
  - From here you can modify the speed / formation / behavior of the units / groups that are moving to that waypoint.
+
+### 2.4 Passing a grenade
+- Using the "Pass grenade" action, you can pass the currently selected grenade or throwable (which will be thrown if you press <kbd>G</kbd>) to another unit.